UDF > Word >

_Word_DocLinkGet

Retourne un objet collection contenant tous les liens d'un document ou un objet lien unique

#include <Word.au3>
_Word_DocLinkGet ( $oDoc [, $iIndex = Default] )

Paramètres

$oDoc Objet document Word
$iIndex [optionnel] Spécifie ce qu'il faut retourner:
    Default - Retourne une collection de tous les liens (par défaut)
    n - Le numéro d'index du lien à retourner (compté à partir de 1)

Valeur de retour

Succès: Retourne une variable pointant sur la collection de liens ou un objet lien unique.
@extended contient le nombre total de liens
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - $oDoc n'est pas un objet
2 - $iIndex est invalide (doit être un entier gt; 0 et < = Hyperlinks.Count) ou le mot-clé Default
3 - Une erreur s'est produite lors de l'accès à la collection d'hyperliens. @extended contient le code d'erreur COM

En relation

_Word_DocLinkAdd

Exemple

Exemple 1

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Crée un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre test.doc en lecture seule
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Example", "Error opening '.\Extras\Test.doc'. @error = " & _
        @error & ", @extended = " & @extended)

;
; Obtient la collection des hyperliens et affiche quelques propriétés
;
Local $oLinks = _Word_DocLinkGet($oDoc)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Example", _
        "Error accessing link collection of the document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $sResult = "Total number of hyperlinks in the document: " & @extended & @CRLF & @CRLF
For $oLink In $oLinks
    $sResult = $sResult & "Text: " & $oLink.TextToDisplay & @CRLF & "Address: " & $oLink.Address & _
            @CRLF & "------------------------------------------" & @CRLF
Next
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Example - Process all hyperlinks", $sResult)

Exemple 2

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Crée un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre test.doc en lecture seule
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Example", "Error opening '.\Extras\Test.doc'. @error = " & _
        @error & ", @extended = " & @extended)

;
; Retourne l'hyperlien numéro 2 et affiche quelques propriétés
;
Local $oLink = _Word_DocLinkGet($oDoc, 2)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Example", _
        "Error accessing link collection of the document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $sResult = "Total number of hyperlinks in the document: " & @extended & @CRLF & @CRLF & _
        "Text: " & $oLink.TextToDisplay & @CRLF & _
        "Address: " & $oLink.Address & @CRLF & _
        "Screentip: " & $oLink.Screentip
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocLinkGet Example - Process hyperlink #2", $sResult)