UDF > Word >

_Word_DocExport

Exporte un document ou une plage au format PDF ou XPS

#include <Word.au3>
_Word_DocExport ( $oDoc, $sFilename [, $iFormat = $WdExportFormatPDF [, $iRange = $WdExportAllDocument [, $iFrom = Default [, $iTo = Default [, $bOpenAfterExport = False [, $bIncludeProperties = True [, $iCreateBookmarks = Default [, $bUseISO19005 = False]]]]]]]] )

Paramètres

$oDoc Objet Document Word à exporter
$sFilename Chemin et nom du fichier exporté
$iFormat [optionnel] Format à utiliser pour l'exportation. Peut prendre toute valeur de l'énumération WdExportFormat
(par défaut = $WdExportFormatPDF)
$iRange [optionnel] Spécifie ce qu'il faut exporter. Peut prendre toute valeur de l'énumération WdExportRange
(par défaut = $WdExportAllDocument)
$iFrom [optionnel] Le numéro de la page à laquelle commencer la publication (par défaut = commence au début)
$iTo [optionnel] Le numéro de la page à laquelle terminer la publication (par défaut = fin à la dernière page)
$bOpenAfterExport [optionnel] True affiche le fichier dans un visualisateur après sa publication (par défaut = False)
$bIncludeProperties [optionnel] True indique que les propriétés du document devraient être inclus (par défaut = True)
$iCreateBookmarks [optionnel] Spécifie s'il faut exporter les signets et le type de signets à exporter.
Peut prendre toute valeur de l'énumération WdExportCreateBookmarks énumération (par défaut)
$bUseISO19005 [optionnel] Indique si l'exportation doit être créé au format PDF/A (PDF autonome) (valeur par défaut = False)

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - $oDoc n'est pas un objet
2 - $sFilename est vide
3 - Erreur retournée lors de l'exportation de l'objet. @extended contient le code d'erreur COM

En relation

_Word_DocPrint

Exemple

Exemple 1

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Crée un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPrint Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre un document test
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPrint Example", _
        "Error opening '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Exporte le document complet avec les valeurs par défaut 
;
Local $sFileName = @TempDir & "\Test1.pdf"
_Word_DocExport($oDoc, $sFileName)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Example", _
        "Error exporting the document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
ShellExecute($sFileName)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Example", _
        "The whole document has successfully been exported to: " & $sFileName)

Exemple 2

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Crée un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPrint Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre un document test
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPrint Example", _
        "Error opening '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Exporte une plage en PDF/A et affiche le fichier exporté
;
; Définit la partie formée des lignes 2 et 3
Local $oRange = _Word_DocRangeSet($oDoc, -1, $wdParagraph, 1, $wdParagraph, 2)
Local $sFileName = @TempDir & "\Test2.pdf"
_Word_DocExport($oRange, $sFileName, Default, $wdExportFromTo, Default, Default, True, Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Example", "Error exporting the document." & _
        @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Example", _
        "The specified range has successfully been exported to: " & $sFileName)

Exemple 3

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Crée un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPrint Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre un document test
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPrint Example", _
        "Error opening '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Exporte la page courante
;
Local $sFileName = @TempDir & "\Test3.pdf"
_Word_DocExport($oDoc, $sFileName, Default, $wdExportCurrentPage)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Example", _
        "Error exporting the document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocExport Example", _
        "The current page has successfully been exported to: " & $sFileName)
ShellExecuteWait($sFileName)