UDF > WinAPIEx > Files & Devices > Files >

_WinAPI_FileEncryptionStatus

Récupère le statut du cryptage du fichier spécifié

#include <WinAPIFiles.au3>
_WinAPI_FileEncryptionStatus ( $sFilePath )

Paramètre

$sFilePath Le nom du fichier dont vous voulez le status de cryptage.

Valeur de retour

Succès: Retourne le status de cryptage ($FILE_*).
Échec: Retourne (-1) et définit @error <> 0, appelez _WinAPI_GetLastError() pour obtenir des informations de code étendu.

Remarque

Les constantes $FILE_* nécessitent #include <APIFilesConstants.au3>

Voir aussi

Consultez FileEncryptionStatus dans la librairie MSDN.

Exemple

#include <APIFilesConstants.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>

Local $sFile = FileOpenDialog('Select File', @ScriptDir, 'All Files (*.*)', 1 + 2)
If @error Then Exit

Switch _WinAPI_FileEncryptionStatus($sFile)
    Case $FILE_ENCRYPTABLE
        If _WinAPI_EncryptFile($sFile) Then
            MsgBox(BitOR($MB_ICONINFORMATION, $MB_SYSTEMMODAL), 'Cryptage de fichier', 'Le fichier est crypté avec succès.')
        Else
            MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Cryptage de fichier', 'Impossible de crypter le fichier.')
        EndIf

    Case $FILE_IS_ENCRYPTED
        If MsgBox(BitOR($MB_YESNO, $MB_ICONQUESTION, $MB_SYSTEMMODAL), 'Cryptage de fichier', 'Le fichier est déjà crypté.' & @CRLF & @CRLF & 'Je le décrypte?') = 6 Then
            If _WinAPI_DecryptFile($sFile) Then
                MsgBox(BitOR($MB_ICONINFORMATION, $MB_SYSTEMMODAL), 'Cryptage dr fichier', 'Le fichier est décrypté avec succès.')
            Else
                MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Cryptage de fichier', 'Impossible de décrypter le fichier.')
            EndIf
        EndIf
    Case Else
        MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Cryptage de fichier', 'Impossible d''effectuer l''opération.')
EndSwitch