UDF > WinAPIEx > System > Windows >

_WinAPI_EnumWindows

Énumère toutes les fenêtres

#include <WinAPISysWin.au3>
_WinAPI_EnumWindows ( [$bVisible = True [, $hWnd = Default]] )

Paramètres

$bVisible [optionnel] Flag de sélection des fenêtres:
True - Retourne seulement les fenêtres visibles
False - Retourne toutes les fenêtres
$hWnd [optionnel] Handle de la fenêtre de départ (fenêtre Desktop par défaut)

Valeur de retour

Retourne un tableau avec le format suivant:
    [0][0] - Nombre de lignes dans le tableau (n)
    [1][0] - Handle de la fenêtre 1
    [1][1] - Nom de la classe de la fenêtre
    ...
    [n][0] - Handle de la fenêtre n
    [n][1] - nom de la classe de la fenêtre

En relation

_WinAPI_EnumWindowsPopup, _WinAPI_EnumWindowsTop

Exemple

#include <Array.au3>
#include <WinAPISysWin.au3>

Example()

Func Example()
    Local $aWindows = _WinAPI_EnumWindows()
    Local $aResult[$aWindows[0][0]][5]
    For $i = 1 To $aWindows[0][0]
        $aResult[$i - 1][0] = $aWindows[$i][0]
        $aResult[$i - 1][1] = $aWindows[$i][1]
        $aResult[$i - 1][2] = WinGetTitle($aWindows[$i][0])
        $aResult[$i - 1][3] = WinGetText($aWindows[$i][0])
        $aResult[$i - 1][4] = WinGetProcess($aWindows[$i][0])
    Next
    _ArrayDisplay($aResult, "_WinAPI_EnumWindows", Default, Default, Default, "Handle|Classe|Titre|Texte|Processus")
EndFunc   ;==>Example