UDF > WinAPIEx > ShellEx >

_WinAPI_DllGetVersion

Obtient une information de version spécifique DLL

#include <WinAPIShellEx.au3>
_WinAPI_DllGetVersion ( $sFilePath )

Paramètre

$sFilePath Le chemin vers le fichier DLL à partir duquel il faut extraire les informations.

Valeur de retour

Succès: Retourne le tableau contenant les informations suivantes:
[0] - La version majeure.
[1] - La version mineure.
[2] - Le numéro de version.
[3] - La plate-forme pour laquelle la DLL a été construite ($DLLVER_PLATFORM_*).
Échec: Définit @error <> 0, @extended peut contenir le code d'erreur HRESULT.

Remarque

Cette fonction n'est pas une API. Elle est exportée par nom de chaque DLL qui l'implémente.
Actuellement, la plupart des DLLs de Windows Shell et des contrôles communs implémente DllGetVersion.
En particulier, shell32.dll, comctl32.dll, shdocvw.dll, et shlwapi.dll.

Voir aussi

Consultez DllGetVersion dans la librairie MSDN.

Exemple

#include <APIShellExConstants.au3>
#include <WinAPIShellEx.au3>

Local Const $sDll = @SystemDir & '\comctl32.dll'

Local $sText
Local $aData = _WinAPI_DllGetVersion($sDll)
Switch @error
    Case 0
        Switch $aData[3]
            Case $DLLVER_PLATFORM_WINDOWS
                $sText = 'Windows 95/98'
            Case $DLLVER_PLATFORM_NT
                $sText = 'NT-based'
            Case Else
                $sText = 'Unknown platform'
        EndSwitch
        ConsoleWrite($sDll & '=> ' & $aData[0] & '.' & $aData[1] & '.' & $aData[2] & '(' & $sText & ')' & @CRLF)
    Case 3
        ConsoleWrite('DllGetVersion n''est pas implémenté dans ' & $sDll & '.' & @CRLF)
    Case Else
        ConsoleWrite('Impossible d''obtenir les informations de version.' & @CRLF)
EndSwitch