UDF > Inet >

_TCPIpToName

Résout l'adresse IP du nom d'hôte(s)

#include <Inet.au3>
_TCPIpToName ( $sIp [, $iOption = 0 [, $hDll = "Ws2_32.dll"]] )

Paramètres

$sIP	Adresse IP au format v4
$iOption	[optionnel] Par défaut = 0 0 = pour retourner la chaîne HostName 1 = pour retourner un tableau (voir Remarque)
$hDll	[optionnel] Handle de Ws2_32.DLL

Valeur de retour

Succès:	Retourne le nom d'hôte ou un tableau (voir Remarque)
Échec:	Retourne ""
@error:	1 - inet_addr DllCall a échoué 2 - inet_addr a échoué 3 - gethostbyaddr DllCall a échoué 4 - gethostbyaddr a échoué, WSAGetLastError = @extended 5 - gethostbyaddr a échoué, WSAGetLastError a échoué 6 - strlen/sZStringRead a échoué 7 - Erreur de lecture Aliases Array

Remarque

Un WSAStartup réussi (Fait par TCPStartup()) est nécessaire.
Si $iOption = 1, le tableau retourné ressemble à ceci:
    $aResult[0] = Nombre d'éléments
    $aResult[1] = "HostName"
    $aResult[2] = "Alias 1"
    $aResult[3] ="Alias 2"
    ...

Exemples

Exemple 1

#include <Inet.au3>
#include <MsgBoxConstants.au3>

Local $aResult, $sResult, $sIP

TCPStartup()
$sIP = TCPNameToIP("autoitscript.com")
$sResult = _TCPIpToName($sIP)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "_TCPIpToName()", "@error = " & @error & @CRLF & "@extended = " & @extended)
Else
    MsgBox($MB_SYSTEMMODAL, "autoitscript.com really is:", $sResult)
EndIf

Exemple 2

#include <Array.au3>
#include <Inet.au3>
#include <MsgBoxConstants.au3>

Local $aResult, $sResult, $sIP

TCPStartup()
$sIP = _GetIP()
$aResult = _TCPIpToName($sIP, 1)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "_TCPIpToName()", "@error = " & @error & @CRLF & "@extended = " & @extended)
Else
    _ArrayDisplay($aResult, "Local Hostname(s)")
EndIf