UDF > IE >

_IEFormElementCheckBoxSelect

Définit la valeur d'un élément donné de formulaire

#include <IE.au3>
_IEFormElementCheckBoxSelect ( ByRef $oObject, $sString [, $sName = "" [, $iSelect = 1 [, $sMode = "byValue" [, $iFireEvent = 1]]]] )

Paramètres

$oObject Variable objet InternetExplorer.Application, objet Form
$sString Valeur utilisée pour déterminer l'élément - traitement selon $sMode
$sName [optionnel] Nom ou Id de la CheckBox(es)
$iSelect [optionnel] spécifie si l'élément doit être coché ou décoché
    -1 = Retourne l'état actuel
    0 = Décoche l'élément
    1 = (par défaut) Coche l'élément
$sMode [optionnel] Spécifie le mode de recherche:
    "byValue" = (par défaut)valeur de la checkbox que vous souhaitez sélectionner
    "byIndex" = index, à partir de 0, de la checkbox que vous souhaitez sélectionner
$iFireEvent [optionnel] Indique s'il faut déclencher les événements OnChange et OnClick après avoir changé la valeur
    0 = ne pas déclencher les événements OnChange ou OnClick après la définition de la valeur
    1 = (par défaut) déclencher les événements OnChange et OnClick après la définition de la valeur

Valeur de retour

Succès: Retourne l'état actuel de la case à cocher si $iSelect = -1, sinon retourne 1.
Échec: Retourne 0 et définit @error <> 0.
@error: 3 ($_IEStatus_InvalidDataType) = Type de donnée invalide
4 ($_IEStatus_InvalidObjectType) = Type d'objet invalide
5 ($_IEStatus_InvalidValue) = Valeur invalide
7 ($_IEStatus_NoMatch) = Aucune correspondance trouvée
@extended: Contient le nombre de paramètres invalides

Remarques

Le paramètre $iFireEvent est significatif seulement si l'élément du formulaire a un événement onChange associé.

$sName est facultatif pour cette fonction.
S'il est omis, la fonction fonctionnera sur une collection de tous les éléments <input type=checkbox> du formulaire.
Si spécifié, la fonction fonctionnera sur une collection d'éléments <input type=checkbox> avec ce nom.

En relation

_IEFormElementGetValue, _IEFormElementOptionSelect, _IEFormElementRadioSelect, _IEFormElementSetValue

Exemple

Exemple 1

; Ouvre un navigateur avec l'exemple de formulaire, obtient une référence sur le formulaire, sélectionne et
; décoche les cases à cocher byValue. Si $s_Name n'est pas spécifié, opère
; sur la collection de tous les éléments <input type=checkbox> du formulaire
; Remarque: Vous aurez probablement besoin de faire défiler la page pour voir les changements
#include <IE.au3>

Local $oIE = _IE_Example("form")
Local $oForm = _IEFormGetObjByName($oIE, "ExampleForm")
For $i = 1 To 3
    _IEFormElementCheckBoxSelect($oForm, "gameBasketball", "", 1, "byValue")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, "gameFootball", "", 1, "byValue")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, "gameTennis", "", 1, "byValue")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, "gameBaseball", "", 1, "byValue")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, "gameBasketball", "", 0, "byValue")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, "gameFootball", "", 0, "byValue")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, "gameTennis", "", 0, "byValue")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, "gameBaseball", "", 0, "byValue")
    Sleep(1000)
Next

_IEQuit($oIE)

Exemple 2

; Ouvre un navigateur avec l'exemple de formulaire, obtient une référence sur le formulaire, sélectionne et
; décoche les cases à cocher byIndex. Si $s_Name n'est pas spécifié, opère
; sur la collection de tous les éléments <input type=checkbox> du formulaire
; Remarque: Vous aurez probablement besoin de faire défiler la page pour voir les changements
#include <IE.au3>

Local $oIE = _IE_Example("form")
Local $oForm = _IEFormGetObjByName($oIE, "ExampleForm")
For $i = 1 To 3
    _IEFormElementCheckBoxSelect($oForm, 3, "", 1, "byIndex")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, 2, "", 1, "byIndex")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, 1, "", 1, "byIndex")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, 0, "", 1, "byIndex")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, 3, "", 0, "byIndex")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, 2, "", 0, "byIndex")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, 1, "", 0, "byIndex")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, 0, "", 0, "byIndex")
    Sleep(1000)
Next

_IEQuit($oIE)

Exemple 3

; Ouvre un navigateur avec l'exemple de formulaire, obtient une référence sur le formulaire, sélectionne et
; décoche les cases à cocher byIndex dans le groupe qui partage le nom checkboxG2Example
; Remarque: Vous aurez probablement besoin de faire défiler la page pour voir les changements
#include <IE.au3>

Local $oIE = _IE_Example("form")
Local $oForm = _IEFormGetObjByName($oIE, "ExampleForm")
For $i = 1 To 3
    _IEFormElementCheckBoxSelect($oForm, 0, "checkboxG2Example", 1, "byIndex")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, 1, "checkboxG2Example", 1, "byIndex")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, 0, "checkboxG2Example", 0, "byIndex")
    Sleep(1000)
    _IEFormElementCheckBoxSelect($oForm, 1, "checkboxG2Example", 0, "byIndex")
    Sleep(1000)
Next

_IEQuit($oIE)