UDF > GDIPlus > Image >

_GDIPlus_DrawImagePoints

Dessine une image à un emplacement spécifié

#include <GDIPlus.au3>
_GDIPlus_DrawImagePoints ( $hGraphic, $hImage, $nULX, $nULY, $nURX, $nURY, $nLLX, $nLLY [, $iCount = 3] )

Paramètres

$hGraphic Handle de l'objet Graphics
$hImage Handle de l'objet Image
$nULX La coordonnée X du coin supérieur gauche de l'image source
$nULY La coordonnée Y du coin supérieur gauche de l'image source
$nURX La coordonnée X du coin supérieur droit de l'image source
$nURY La coordonnée Y du coin supérieur droit de l'image source
$nLLX La coordonnée X du coin inférieur gauche de l'image source
$nLLY La coordonnée Y du coin inférieur gauche de l'image source
$iCount [optionnel] Le nombre de points (x, y) de la structure.

Valeur de retour

Succès: Retourne True
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur GPSTATUS ( GDIP_ERR*).

Remarque

La valeur du paramètre $iCount doit être égal à 3 pour spécifier les coordonnées du coin supérieur gauche, coin supérieur droit, et le coin inférieur gauche du parallélogramme.
La coordonnée du coin en bas à droite, la largeur et la hauteur de l'image, sont calculés à l'aide des trois coordonnées données.
L'image est redimensionnée à la taille du parallélogramme.

Voir aussi

Consultez GdipDrawImagePoints dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPIHObj.au3>

Example()

Func Example()
    Local $hBitmap1, $hBitmap2, $hImage1, $hImage2, $hGraphic

    ; Initialise la bibliothèque GDI+
    _GDIPlus_Startup()

    ; Capture l'écran complet
    $hBitmap1 = _ScreenCapture_Capture("")
    $hImage1 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap1)

    ; Capture une région d'écran
    $hBitmap2 = _ScreenCapture_Capture("", 0, 0, 400, 300)
    $hImage2 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap2)

    ; Dessine une image dans une autre
    $hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage1)

    _GDIPlus_DrawImagePoints($hGraphic, $hImage2, 100, 100, 600, 170, 130, 570)

    ; Dessine un cadre autour de l'image insérée
    _GDIPlus_GraphicsDrawRect($hGraphic, 100, 100, 400, 300)

    ; Enregistre l'image résultante
    _GDIPlus_ImageSaveToFile($hImage1, @MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Nettoie les ressources
    _GDIPlus_ImageDispose($hImage1)
    _GDIPlus_ImageDispose($hImage2)
    _WinAPI_DeleteObject($hBitmap1)
    _WinAPI_DeleteObject($hBitmap2)

    ; Arrête la bibliothèque GDI+
    _GDIPlus_Shutdown()

    ShellExecute(@MyDocumentsDir & "\GDIPlus_Image.jpg")
EndFunc   ;==>Example