UDF > Excel >


_Excel_SheetList

Retourne une liste de toutes les feuilles d'un classeur donné

#include <Excel.au3>
_Excel_SheetList ( $oWorkbook )

Paramètre

$oWorkbook L'objet classeur

Valeur de retour

Succès: Retourne un tableau à deux dimensions indexé à partir de 0 avec les informations suivantes:
    0 - Le nom de la feuille de calcul
    1 - L'objet feuille de calcul
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - $oWorkbook n'est pas un objet ou n'est pas un objet classeur

Exemple

#include <Array.au3>
#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Crée un objet Excel et ouvre un classeur
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_SheetList-Exemple", "Erreur lors de la création de l'objet Excel." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, @ScriptDir & "\Extras\_Excel2.xls")
If @error Then
    MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_SheetList-Exemple", "Erreur lors de l'ouverture du classeur '" & @ScriptDir & "\Extras\_Excel2.xls'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; Affiche une liste de toutes les feuilles du classeur
Local $aWorkSheets = _Excel_SheetList($oWorkbook)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_SheetList-Exemple 1", "Erreur lors de l'énumération des feuilles." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
_ArrayDisplay($aWorkSheets, "UDF Excel: _Excel_SheetList-Exemple 1")