UDF > Excel >

_Excel_Export

Exporte un classeur, une feuille de calcul, un graphique ou une plage au format PDF ou XPS

#include <Excel.au3>
_Excel_Export ( $oExcel, $vObject, $sFileName [, $iType = $xlTypePDF [, $iQuality = $xlQualityStandard [, $bIncludeProperties = True [, $iFrom = Default [, $iTo = Default [, $bOpenAfterPublish = Default]]]]]] )

Paramètres

$oExcel Objet application Excel
$vObject Objet classeur, feuille de calcul, graphique ou plage à exporter au format PDF ou XPS. La plage peut être spécifiée au format $xlA1
$sFilename Chemin/nom du fichier exporté
$iType [optionnel] $xlTypePDF ou $xlTypeXPS de l'énumération XlFixedFormatType (par défaut = $xlTypePDF)
$iQuality [optionnel] Toute valeur de l'énumération XlFixedFormatQuality (par défaut = $xlQualityStandard)
$bIncludeProperties [optionnel] True indique que les propriétés du document devraient être inclus (par défaut = True)
$iFrom [optionnel] Le numéro de page où commencer le traitement (par défaut = mot-clé Default = commencer au début)
$iTo [optionnel] Le numéro de page où terminer le traitement (par défaut = mot-clé Default = fin à la dernière page)
$bOpenAfterPublish [optionnel] True affiche le fichier dans un afficheur après sa création (par défaut = False)

Valeur de retour

Succès: Retourne l'objet plage exportée.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - $oExcel n'est pas un objet ou n'est pas un objet application
2 - $vObject n'est pas un objet ou une plage $xlA1 invalide. @error contient le code d'erreur COM
3 - $sFilename est vide
4 - Erreur d'exportation d'objet. @extended contient le code d'erreur COM retourné par la méthode ExportAsFixedFormat

En relation

_Excel_Print

Exemples

Exemple 1

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Crée un objet Excel et ouvre un exemple de classeur
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Export-Exemple", "Erreur lors de la création de l'objet Excel." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, @ScriptDir & "\Extras\_Excel1.xls", True)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Export-Exemple", "Erreur lors de l'ouverture du classeur '" & @ScriptDir & "\Extras\_Excel1.xls'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; *****************************************************************************
; Exporte la plage de cellules A1:E10 de la feuille de calcul active au format PDF et affiche le fichier.
; *****************************************************************************
Local $sOutput = @TempDir & "\_Excel1_1.pdf"
_Excel_Export($oExcel, "A1:E10", $sOutput, Default, Default, Default, Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Export-Exemple 1", "Erreur lors de la sauvegarde de la plage en '" & $sOutput & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Export-Exemple 1", "L'objet Range est exporté avec succès sous le nom '" & $sOutput & "'.")

Exemple 2

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Crée un objet Excel et ouvre un exemple de classeur
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Export-Exemple", "Erreur lors de la création de l'objet Excel." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, @ScriptDir & "\Extras\_Excel1.xls", True)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Export-Exemple", "Erreur lors de l'ouverture du classeur '" & @ScriptDir & "\Extras\_Excel1.xls'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; *****************************************************************************
; Exporte la totalité du classeur au format PDF.
; *****************************************************************************
Local $sOutput = @TempDir & "\_Excel1_2.pdf"
_Excel_Export($oExcel, $oWorkbook, $sOutput)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Export-Exemple 2", "Erreur lors de la sauvegarde du classeur en '" & $sOutput & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Export-Exemple 2", "Le classeur entier a été exporté avec succès sous le nom '" & $sOutput & "'.")