UDF > Excel >


_Excel_BookSave

Sauvegarde le classeur spécifié

#include <Excel.au3>
_Excel_BookSave ( $oWorkbook )

Paramètre

$oWorkbook Objet classeur à sauvegarder

Valeur de retour

Succès: Retourne @extended définnit à:
    0 - Le fichier n'a pas été sauvegardé parce qu'il n'a pas été modifié depuis la dernière sauvegarde ou depuis son ouverture
    1 - Le fichier a été sauvegardé parce qu'il a été modifié depuis la dernière sauvegarde ou depuis l'ouverture
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - $oWorkbook n'est pas un objet ou n'est pas un objet classeur
2 - Une erreur s'est produite lors de l'enregistrement du classeur. @extended contient le code d'erreur COM

Remarque

Un classeur nouvellement créé doit sauvegardé avant à l'aide de _Excel_BookSaveAs().

En relation

_Excel_BookSaveAs

Exemple

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Crée un objet Excel
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox(16, "UDF Excel: _Excel_BookOpen-Exemple", "Erreur lors de la création de l'objet Excel." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; *****************************************************************************
; Crée un nouveau classeur, écrit des données et l'enregistre dans @tempdir
; *****************************************************************************
; Crée le nouveau classeur
Local $oWorkbook = _Excel_BookNew($oExcel)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_BookSave-Exemple 1", "Erreur lors de la création du nouveau classeur." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Écrit un mot dans la cellule A1
_Excel_RangeWrite($oWorkbook, Default, "Test", "A1")
If Not IsObj($oWorkbook) Or ObjName($oWorkbook, 1) <> "_Workbook" Then Exit SetError(1, 0, 0)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_BookSave-Exemple 1", "Erreur lors de l'écriture dans la cellule 'A1'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Enregistre le classeur dans @tempdir sous le nom _Excel.xls (remplacement du fichier existant)
_Excel_BookSaveAs($oWorkbook, @TempDir & "\_Excel.xls", Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_BookSave-Exemple 1", "Erreur lors de la sauvegarde du classeur." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Écrit un mot dans la cellule B1
_Excel_RangeWrite($oWorkbook, Default, "2nd Test", "B1")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_BookSave-Exemple 1", "Erreur lors de l'écriture dans la cellule 'A1'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Enregistre le classeur modifié
_Excel_BookSave($oWorkbook)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_BookSave-Exemple 1", "Erreur lors de la sauvegarde du classeur." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_BookSave-Exemple 1", "Le classeur a été sauvegardé avec succès sous le nom '" & @TempDir & "\_Excel.xls'.")