UDF > Excel >

_Excel_BookAttach

Obtient la première instance d'un classeur Excel dont le nom concorde à une chaîne donnée, dans un mode de recherche donné

#include <Excel.au3>
_Excel_BookAttach ( $sString [, $sMode = "FilePath" [, $oInstance = Default]] )

Paramètres

$sString Nom caractéristique du classeur cherché, supposé ouvert
$sMode [optionnel] Spécifie le mode de recherche:
    FileName - Nom du classeur ouvert
    FilePath - Nom complet du classeur ouvert (par défaut)
    Title - Titre de la fenêtre Excel
$oInstance [optionnel] Instance de l'objet Excel où effectuer la recherche (par défaut, Default = toutes les instances)

Valeur de retour

Succès: Retourne l'objet classeur Excel.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - Une erreur s'est produite ou $sString ne peut pas être trouvée dans l'un des classeurs ouverts. @extended contient le code d'erreur COM
2 - $sMode est invalide

En relation

_Excel_BookClose, _Excel_BookNew, _Excel_BookOpen, _Excel_BookOpenText

Exemples

Exemple 1

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Crée un objet Excel et ouvre un classeur
Local $sWorkbook = @ScriptDir & "\Extras\_Excel1.xls"
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_BookAttach-Exemple 1", "Erreur lors de la création de l'objet Excel." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, $sWorkbook)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_BookAttach-Exemple", "Erreur lors de l'ouverture du classeur '" & $sWorkbook & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; *****************************************************************************
; Obtient le premier classeur dont le nom complet de fichier concorde
; *****************************************************************************
$oWorkbook = _Excel_BookAttach($sWorkbook)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_BookAttach-Exemple 1", "Erreur lors de la recherche de '" & $sWorkbook & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_BookAttach-Exemple 1", "Recherche par 'nom complet':" & @CRLF & @CRLF & "Classeur trouvé avec succès: '" & $sWorkbook & "'." & @CRLF & @CRLF & "Valeur de la cellule B3: " & $oWorkbook.Activesheet.Range("B3").Value)

Exemple 2

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Crée un objet Excel et ouvre un classeur
Local $oExcel = _Excel_Open()
If @error <> 0 Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_BookAttach-Exemple 2", "Erreur lors de la création de l'objet Excel." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, @ScriptDir & "\Extras\_Excel1.xls")
If @error Then
    MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_BookAttach-Exemple 2", "Erreur lors de l'ouverture du classeur '" & @ScriptDir & "\Extras\_Excel1.xls'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; ****************************************************************************
; Obtient le premier classeur dont le nom de fichier concorde
; ****************************************************************************
Local $sWorkbook = "_Excel1.xls"
$oWorkbook = _Excel_BookAttach($sWorkbook, "filename")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_BookAttach-Exemple 2", "Erreur lors de la recherche de '" & $sWorkbook & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_BookAttach-Exemple 2", "Recherche par 'nom de fichier':" & @CRLF & @CRLF & "Classeur trouvé avec succès: '" & $sWorkbook & "'." & @CRLF & @CRLF & "Valeur de la cellule A2: " & $oWorkbook.Activesheet.Range("A2").Value)