+

UDF > Misc >

_ChooseFont

Crée une boîte de dialogue Font qui permet à l'utilisateur de choisir les attributs d'une police logique

#include <Misc.au3>
_ChooseFont ( [$sFontName = "Courier New" [, $iPointSize = 10 [, $iFontColorRef = 0 [, $iFontWeight = 0 [, $bItalic = False [, $bUnderline = False [, $bStrikethru = False [, $hWndOwner = 0]]]]]]]] )

Paramètres

$sFontName [optionnel] Nom de la police par défaut
$iPointSize [optionnel] Taille en points de la police
$iFontColorRef [optionnel] Couleur rgb COLORREF
$iFontWeight [optionnel] Graisse de la Police
$bItalic [optionnel] Italique
$bUnderline [optionnel] Souligné
$bStrikethru [optionnel] Barré
$hWndOwner [optionnel] Handle de la fenêtre qui est propriétaire de la boîte de dialogue

Valeur de retour

Succès: Retourne un tableau dans le format suivant:
    [0] - contient le nombre d'éléments du tableau
    [1] - attributs = BitOR de italique:2, souligné:4, barré:8
    [2] - nom de la police
    [3] - taille de la police en points
    [4] - graisse de la police de 0 à 1000
    [5] - couleur rgb COLORREF
    [6] - couleur BGR en hexadécimal
    [7] - couleur RGB en hexadécimal
Échec: Définit @error <> 0.

Exemples

Exemple 1

#include <Misc.au3>
#include <MsgBoxConstants.au3>

Local $a_vFont = _ChooseFont("Arial", 8)
If (@error) Then
    MsgBox($MB_SYSTEMMODAL, "", "Error _ChooseFont: " & @error)
Else
    MsgBox($MB_SYSTEMMODAL, "", "Font Name: " & $a_vFont[2] & @CRLF & "Size: " & $a_vFont[3] & @CRLF & "Weight: " & $a_vFont[4] & @CRLF & "COLORREF rgbColors: " & $a_vFont[5] & @CRLF & "Hex BGR Color: " & $a_vFont[6] & @CRLF & "Hex RGB Color: " & $a_vFont[7])
EndIf

Exemple 2

#include <Misc.au3>
#include <MsgBoxConstants.au3>

Local $a_vFont = _ChooseFont()
If (@error) Then
    MsgBox($MB_SYSTEMMODAL, "ERROR", "Error _ChooseFont: " & @error)
    Exit
Else
    MsgBox($MB_SYSTEMMODAL, "", "Font Name: " & $a_vFont[2] & @CRLF & "Size: " & $a_vFont[3] & @CRLF & "Weight: " & $a_vFont[4] & @CRLF & "COLORREF rgbColors: " & $a_vFont[5] & @CRLF & "Hex BGR Color: " & $a_vFont[6] & @CRLF & "Hex RGB Color: " & $a_vFont[7])
EndIf

Exemple 3

#include <Misc.au3>
#include <MsgBoxConstants.au3>

Local $a_vFont = _ChooseFont()

Local $sFontName = $a_vFont[2]
Local $iFontSize = $a_vFont[3]
Local $iColorRef = $a_vFont[5]
Local $iFontWeight = $a_vFont[4]
Local $bItalic = BitAND($a_vFont[1], 2)
Local $bUnderline = BitAND($a_vFont[1], 4)
Local $bStrikethru = BitAND($a_vFont[1], 8)
$a_vFont = _ChooseFont($sFontName, $iFontSize, $iColorRef, $iFontWeight, $bItalic, $bUnderline, $bStrikethru)
If (@error) Then
    MsgBox($MB_SYSTEMMODAL, "", "Error _ChooseFont: " & @error)
Else
    MsgBox($MB_SYSTEMMODAL, "", "Font Name: " & $a_vFont[2] & @CRLF & "Size: " & $a_vFont[3] & @CRLF & "Weight: " & $a_vFont[4] & @CRLF & "COLORREF rgbColors: " & $a_vFont[5] & @CRLF & "Hex BGR Color: " & $a_vFont[6] & @CRLF & "Hex RGB Color: " & $a_vFont[7])
EndIf