UDF > Array >

_ArrayMin

Retourne la plus petite valeur d'un tableau 1D ou 2D

#include <Array.au3>
_ArrayMin ( Const ByRef $aArray [, $iCompNumeric = 0 [, $iStart = -1 [, $iEnd = -1 [, $iSubItem = 0]]]] )

Paramètres

$aArray	Tableau à traiter
$iCompNumeric	[optionnel] Méthode de comparaison : 0 - Comparaison alphanumérique 1 - Comparaison numérique
$iStart	[optionnel] Index du tableau où commencer la recherche
$iEnd	[optionnel] Index du tableau où terminer la recherche
$iSubItem	[optionnel] Colonne du tableau où effectuer la recherche

Valeur de retour

Succès:	Retourne la valeur minimum du tableau.
Échec:	Définit @error <> 0 (voir _ArrayMinIndex() pour une description de @error ).

En relation

_ArrayMax, _ArrayMaxIndex, _ArrayMinIndex, _ArrayUnique

Exemple

#include <Array.au3>
#include <MsgBoxConstants.au3>

Local $aArray = StringSplit("4,2,06,8,12,5", ",")

MsgBox($MB_SYSTEMMODAL, 'Valeur chaîne Minimale', _ArrayMin($aArray, 0, 1))
MsgBox($MB_SYSTEMMODAL, 'Valeur numérique Minimale', _ArrayMin($aArray, 1, 1))

Local $aArray[4][4]
For $i = 0 To 3
    For $j = 0 To 3
        $aArray[$i][$j] = Random(0, 99, 1)
    Next
Next
_ArrayDisplay($aArray, "Tableau 2D")
MsgBox($MB_SYSTEMMODAL, 'Valeur Numérique minimale dans la colonne 2', _ArrayMin($aArray, 1, 0, 0, 2))