UDF > Date >

_Date_Time_FileTimeToStr

Décode une date/heure de fichier en une chaîne date/heure

#include <Date.au3>
_Date_Time_FileTimeToStr ( ByRef $tFileTime [, $iFmt = 0] )

Paramètres

$tFileTime Structure $tagFILETIME
$iFmt [optionnel] 0 pour le format mm/dd/aaaa hh:mm:ss (par défaut)
1 pour le format aaaa/mm/dd hh:mm:ss

Valeur de retour

Retourne une date/heure sous forme d'une chaîne formatée selon $iFmt.

En relation

$tagFILETIME

Exemple

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tFile

    ; Crée la GUI
    GUICreate("Temps", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Encode une heure de fichier
    $tFile = _Date_Time_EncodeFileTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC)
    MemoWrite("Date/heure actuelles . : " & _Date_Time_FileTimeToStr($tFile))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite