[Ex] Saisie semi-automatique

[Iste]

Salutations,

Ayant besoin de rajouter de la saisie semi-auto dans l'une de mes editbox, je me suis dis que j'allais chercher sur le net... ha ben, rien trouver.. vais demander de l'aide alors... ha ben, en faite je vais commencer par essayer de le faire moi meme !

Et au final, voici ce que ca donne :

Code : Tout sélectionner

#include <GuiEdit.au3>
#include <Misc.au3>
#include <GUIConstantsEx.au3>
#Include <Array.au3>

$Form1 = GUICreate("Form1", 500, 500)
$Edit = GUICtrlCreateEdit("", 0, 0, 500, 500)
GUISetState(@SW_SHOW)


;~ $phrases = IniReadSection("phrases.ini", "prhases")
Dim $phrases[10][2]
$phrases[0][0] = 4
$phrases[1][1] = "Bonjour"
$phrases[2][1] = "Salut"
$phrases[3][1] = "Une longue phrase avec des espace et des petits oignons !"
$phrases[4][1] = "Bonbon"

;~ _ArrayUnique($phrases,2)
;~ _ArraySort($phrases)
$modif = 1
$lettre = ""

While 1
    $nMsg = GUIGetMsg()
    Select
        Case $nMsg = $GUI_EVENT_CLOSE
            Exit
        Case _GUICtrlEdit_GetModify($Edit) = "True"
            If Not _IsPressed("08") Then
                $pos = _GUICtrlEdit_GetSel($Edit)
                If Not StringIsAlNum(StringRight(StringLeft(_GUICtrlEdit_GetText($Edit), $pos[0] - 1), 1)) Or $modif > 1 Then
                    $lettre = StringRight(StringLeft(_GUICtrlEdit_GetText($Edit), $pos[0]), $modif)
                    For $i = 1 To $phrases[0][0] + 1
                        If $i = $phrases[0][0] + 1 Then
                            If $modif > 1 Then
                                If StringRight(StringLeft(_GUICtrlEdit_GetText($Edit), $pos[0]), 1) = " " Then
                                    _GUICtrlEdit_Undo($Edit)
                                    $pos = _GUICtrlEdit_GetSel($Edit)
                                    _GUICtrlEdit_SetSel($Edit, $pos[1], $pos[1])
                                    _GUICtrlEdit_InsertText($Edit, " ", $pos[1])
                                EndIf
                            EndIf
                            $modif = 1
                            ExitLoop
                        EndIf
                        If $lettre = StringLeft($phrases[$i][1], $modif) Then
                            _GUICtrlEdit_InsertText($Edit, StringRight($phrases[$i][1], StringLen($phrases[$i][1]) - $modif), $pos[0])
                            _GUICtrlEdit_SetSel($Edit, $pos[0], $pos[0] + StringLen($phrases[$i][1]) - $modif)
                            $modif += 1
                            ExitLoop
                        EndIf
                    Next
                EndIf
            EndIf
            _GUICtrlEdit_SetModify($Edit, "False")

    EndSelect
WEnd

Je n'ai pas trouvé de bug pour le moment, toute foi je ne suis pas bien sur que ce soit parfait.
Si quelqu'un a mieux a proposer, qui se manifeste

[orax]

Intéressant. J'ai également cherché pour voir s'il existe déjà quelque chose mais je n'ai rien trouvé. Par contre, ça serait encore mieux si le script allait chercher les mots directement dans le texte au lieu de devoir les rentrer à l'avance.



Edité :
Mise à jour du script que j'avais commencé. Ca affiche une Listebox pour la complétion. Il n'y a pas de gestion de la souris, par contre les touches "haut, bas, droite, gauche, début, fin, page haut, page bas et entrée" permettent de sélectionner le mot.

► Afficher le texte

Code : Tout sélectionner

#include <GuiEdit.au3>
#include <Misc.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ListBoxConstants.au3>
#include <Array.au3>
#include <WinAPI.au3>
#include <GUIListBox.au3>
#include <Constants.au3>

Opt("MustDeclareVars", 1)

;
; ça va remplir le "edit" pour tester la complétion :o)
;
Global $aaa
For $i = 0 To 1000
    $aaa &= "test" & Random(100000, 999999, 1) & " "
Next
;~ ClipPut($aaa)

Global Const $NULL = ""

; constante servant à définir ce qui sépare les mots
Global Const $SEPARATEUR_DE_MOTS[5] = [ _
        @CRLF, _
        @CR, _
        @LF, _
        @TAB, _
        " "]

Global $completion = GUICreate("Complétion", 500, 500)
Global $edit = GUICtrlCreateEdit("", 0, 0, 500, 500)
Global $hEdit = GUICtrlGetHandle($edit)
Global $guiListeCompletion, $listeCompletion, $hListeCompletion
Global $listeCompletionAffichee = False
Global $debutMot

;
; met le texte dans le "edit" pour tester la complétion
;
GUICtrlSetData($edit, $aaa)

creeListeCompletion()

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

; http://msdn.microsoft.com/en-us/library/ms633570&#40;VS.85&#41;.aspx
Global $hWndproc_Edit = DllCallbackRegister('wndproc_Edit', 'lparam', 'hwnd;uint;wparam;lparam')
If $hWndproc_Edit = 0 Then Exit
Global $hAncienWNDPROC_edit = _WinAPI_GetWindowLong(GUICtrlGetHandle($edit), $GWL_WNDPROC)
_WinAPI_SetWindowLong(GUICtrlGetHandle($edit), $GWL_WNDPROC, DllCallbackGetPtr($hWndproc_Edit))

GUISetState(@SW_SHOW, $completion)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

DllCallbackFree($hWndproc_Edit)
GUIDelete()

Func completion($txt, $emplacement_curseur, $separateur)
    Local $i, $index, $temp, $t, $retCompletionMots, $debutDoc_mot

    If Not $txt Then Return SetError(1, "", "")

    ; récupère le texte du début du document jusqu'au mot à compléter
    $debutDoc_mot = StringLeft($txt, $emplacement_curseur)

    ; recherche le début du mot
    For $i = 1 To StringLen($txt)
        $temp = StringMid($debutDoc_mot, StringLen($debutDoc_mot) - $i + 1, 1)
        $index = _ArraySearch($separateur, $temp)
        If $index <> -1 Then
            $debutMot = StringRight($debutDoc_mot, $i - 1)
            ExitLoop
        EndIf
    Next
    If Not $debutMot Then $debutMot = $txt

    ; remplace les caractères spéciaux
    $debutMot = StringRegExpReplace($debutMot, _
            '(?x)([\$ \\ \( \) \| \. \[ \]])', _
            "\\\1")

    ; recherche le mot dans le texte
;~  $t = TimerInit()
    If $debutMot Then $retCompletionMots = StringRegExp($txt, _
            '(?ixs)' & _
            '(?>' & _
            '  (?<=\A|\s) (' & $debutMot & '[^\s]+)' & _
            ')' & _
            '(?!' & _
            '  .*? (?:\A|\s) \1 (?:\s|\z)' & _
            ')', _
            3)
;~  MsgBox(0, "", TimerDiff($t))

    ; si le mot est trouvé
    If UBound($retCompletionMots) Then
        Return $retCompletionMots
    Else
        Return SetError(1, "", "")
    EndIf
EndFunc   ;==>completion

Func creeListeCompletion()
    $guiListeCompletion = GUICreate("", _
            200, 150, 0, 0, _
            $WS_POPUP, _
            $WS_EX_WINDOWEDGE, _
            $completion)

    $listeCompletion = GUICtrlCreateList("", 0, 0, 200, 150)
    $hListeCompletion = GUICtrlGetHandle($listeCompletion)
EndFunc   ;==>creeListeCompletion

Func afficheListeCompletion()
    Local $ret, $tRect
    Local $x_edit, $y_edit, $x_curseur, $y_curseur

    ; récupère les coordonnées du contrôle "edit"
    $tRect = _WinAPI_GetWindowRect($hEdit)
    $x_edit = DllStructGetData($tRect, "Left")
    $y_edit = DllStructGetData($tRect, "Top")

    ; récupère les coordonnées de l'emplacement du curseur
    $ret = _GUICtrlEdit_GetSel($hEdit)
    $ret = _GUICtrlEdit_PosFromChar($hEdit, $ret[0] - 1)
    $x_curseur = $ret[0]
    $y_curseur = $ret[1]

    ; déplace la liste sous le curseur
    WinMove($guiListeCompletion, "", $x_edit + $x_curseur, $y_edit + $y_curseur + 20)

    ; sélectionne le premier élément
    _GUICtrlListBox_SetCurSel($hListeCompletion, 0)
    GUISetState(@SW_SHOWNOACTIVATE, $guiListeCompletion)

    $listeCompletionAffichee = True
EndFunc   ;==>afficheListeCompletion

Func cacheListeCompletion()
    GUISetState(@SW_HIDE, $guiListeCompletion)
    $listeCompletionAffichee = False
EndFunc   ;==>cacheListeCompletion

Func metDonneesListeCompletion($donnees)
    effaceListeCompletion()
    GUICtrlSetData($listeCompletion, $donnees)
EndFunc   ;==>metDonneesListeCompletion

Func effaceListeCompletion()
    _GUICtrlListBox_ResetContent($hListeCompletion)
EndFunc   ;==>effaceListeCompletion

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam, $ilParam

    Local $posDansEdit, $retCompletionMots

    Switch $ilParam
        Case $hEdit
            Switch _WinAPI_HiWord($iwParam)
                Case $EN_CHANGE
                    ; affichage de la liste de complétion
                    
                    $posDansEdit = _GUICtrlEdit_GetSel($edit)

                    $retCompletionMots = completion(GUICtrlRead($edit), $posDansEdit[0], $SEPARATEUR_DE_MOTS)

                    If UBound($retCompletionMots) Then
                        $retCompletionMots = _ArrayToString($retCompletionMots, "|")
                        metDonneesListeCompletion($retCompletionMots)
                        afficheListeCompletion()
                    Else
                        If $listeCompletionAffichee Then
                            effaceListeCompletion()
                            cacheListeCompletion()
                        EndIf
                    EndIf
            EndSwitch
    EndSwitch
EndFunc   ;==>WM_COMMAND

Func wndproc_Edit($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam, $ilParam

    Local $ret, $posDansListe, $posDansEdit, $texteElement, $nbElements, $finMotCompletion

    ; si la liste de complétion n'est affichée alors on ne fait rien
    If $listeCompletionAffichee = False Then
        $ret = _WinAPI_CallWindowProc($hAncienWNDPROC_edit, $hWnd, $iMsg, $iwParam, $ilParam)
        If Not @error Then Return $ret
    EndIf

    Switch $iMsg
        Case $WM_CHAR
            Switch $iwParam
                Case 13 ; entrée
                    $posDansListe = _GUICtrlListBox_GetCurSel($hListeCompletion)

                    ; on récupère le mot dans la liste
                    $texteElement = _GUICtrlListBox_GetText($hListeCompletion, $posDansListe)

                    ; on récupère la fin du mot qui reste à compléter
                    $finMotCompletion = StringTrimLeft($texteElement, StringLen($debutMot))

                    ; on ajoute la complétion au mot
                    $posDansEdit = _GUICtrlEdit_GetSel($edit)
                    _GUICtrlEdit_InsertText($edit, $finMotCompletion, $posDansEdit[0])

                    $ret = _WinAPI_CallWindowProc($hAncienWNDPROC_edit, $hWnd, $iMsg, $NULL, $ilParam)
                    If Not @error Then Return $ret
            EndSwitch

        Case $WM_KEYDOWN
            Switch $iwParam
                Case 33 ; page haut
                    $posDansListe = _GUICtrlListBox_GetCurSel($hListeCompletion)

                    If $posDansListe - 5 < $nbElements Then
                        _GUICtrlListBox_SetCurSel($hListeCompletion, 0)
                    Else
                        _GUICtrlListBox_SetCurSel($hListeCompletion, $posDansListe - 5)
                    EndIf

                    $ret = _WinAPI_CallWindowProc($hAncienWNDPROC_edit, $hWnd, $iMsg, $NULL, $ilParam)
                    If Not @error Then Return $ret

                Case 34 ; page bas
                    $nbElements = _GUICtrlListBox_GetCount($hListeCompletion) - 1
                    $posDansListe = _GUICtrlListBox_GetCurSel($hListeCompletion)

                    If $posDansListe + 5 > $nbElements Then
                        _GUICtrlListBox_SetCurSel($hListeCompletion, $nbElements)
                    Else
                        _GUICtrlListBox_SetCurSel($hListeCompletion, $posDansListe + 5)
                    EndIf

                    $ret = _WinAPI_CallWindowProc($hAncienWNDPROC_edit, $hWnd, $iMsg, $NULL, $ilParam)
                    If Not @error Then Return $ret

                Case 35 ; fin
                    $nbElements = _GUICtrlListBox_GetCount($hListeCompletion) - 1
                    _GUICtrlListBox_SetCurSel($hListeCompletion, $nbElements)

                    $ret = _WinAPI_CallWindowProc($hAncienWNDPROC_edit, $hWnd, $iMsg, $NULL, $ilParam)
                    If Not @error Then Return $ret

                Case 36 ; début
                    _GUICtrlListBox_SetCurSel($hListeCompletion, 0)

                    $ret = _WinAPI_CallWindowProc($hAncienWNDPROC_edit, $hWnd, $iMsg, $NULL, $ilParam)
                    If Not @error Then Return $ret

                Case 37 ; gauche
                    cacheListeCompletion()

                Case 38 ; haut
                    $posDansListe = _GUICtrlListBox_GetCurSel($hListeCompletion)

                    If $posDansListe = 0 Then
                        ; si on est déjà en haut de la liste alors on sélectionne le dernier
                        _GUICtrlListBox_SetCurSel($hListeCompletion, _
                                _GUICtrlListBox_GetCount($hListeCompletion) - 1)
                    Else
                        ; sinon on sélectionne l'élément suivant
                        _GUICtrlListBox_SetCurSel($hListeCompletion, _
                                $posDansListe - 1)
                    EndIf

                    $ret = _WinAPI_CallWindowProc($hAncienWNDPROC_edit, $hWnd, $iMsg, $NULL, $ilParam)
                    If Not @error Then Return $ret

                Case 39 ; droite
                    cacheListeCompletion()

                Case 40 ; bas
                    $posDansListe = _GUICtrlListBox_GetCurSel($hListeCompletion)

                    If $posDansListe = _GUICtrlListBox_GetCount($hListeCompletion) - 1 Then
                        ; si on est déjà en bas de la liste alors on sélectionne le premier
                        _GUICtrlListBox_SetCurSel($hListeCompletion, 0)
                    Else
                        ; sinon on sélectionne l'élément suivant
                        _GUICtrlListBox_SetCurSel($hListeCompletion, _
                                $posDansListe + 1)
                    EndIf

                    $ret = _WinAPI_CallWindowProc($hAncienWNDPROC_edit, $hWnd, $iMsg, $NULL, $ilParam)
                    If Not @error Then Return $ret
            EndSwitch
    EndSwitch

    $ret = _WinAPI_CallWindowProc($hAncienWNDPROC_edit, $hWnd, $iMsg, $iwParam, $ilParam)
    If Not @error Then Return $ret
EndFunc   ;==>wndproc_Edit

[Iste]

ha oui pas bete, moi jétai parti sur une base de donnée prédéfinie, un peu comme les noms de fonctions
Mais sinon, hum...

Code : Tout sélectionner

#include <Array.au3>
$var = ClipGet()
$result = StringRegExp ($var,"([a-zA-Z0-9]+)",3)
_ArrayDisplay($result)

Edit : j'ai essayé de placer ca dans la boucle :

Code : Tout sélectionner

    $var = StringRegExp ( _GUICtrlEdit_GetText($Edit) ,"([a-zA-Z0-9]+)",3)
    _ArrayConcatenate($phrases , $var)
    $phrases = _ArrayUnique($phrases )
    _ArrayDelete($phrases,0)
    $phrases[0] = UBound($phrases)
;~  _ArrayDisplay($phrases)

en modifiant bien la variable $phrases dans le code d'apres, mais ca plante :/

[orax]

Ben en fait je ne comprend pas. Le StringRegExp ( _GUICtrlEdit_GetText($Edit) ,"([a-zA-Z0-9]+)",3) va récupérer tous les caractères alphanumériques. Il n'y a pas de complétion là.

[Iste]

StringRegExp ( _GUICtrlEdit_GetText($Edit) ,"([a-zA-Z0-9]+)",3) renvoi uniquement les mot complet compris entre deux "trucs qui sont pas des lettre ou des chiffre" ce qui tombe bien vu que mon script prend que ca pour la saisie semi auto

Il ne prend pas les lettre et chiffre une a une, car pour ca il faudrait rajouter un "?"
StringRegExp ( _GUICtrlEdit_GetText($Edit) ,"([a-zA-Z0-9]+?)",3)

Enfin essaye tu véras, ca marche tres bien ^^

[orax]

Ben oui mais il faudrait que ça retourne le mot qu'on cherche pour pouvoir le compléter. Ou alors je n'ai rien compris.
J'ai intégré le script que j'ai mis à mon premier message :

► Afficher le texte

Code : Tout sélectionner

#include <GuiEdit.au3>
#include <Misc.au3>
#include <GUIConstantsEx.au3>
#include <Array.au3>

Global $debutMot

; séparateur de mots
Global $a[5]
$a[0] = @CRLF
$a[1] = @CR
$a[2] = @LF
$a[3] = @TAB
$a[4] = " "

;~ $texte = "bonj"
;~ $texte=ClipGet()
;~ MsgBox(0,"","ooo")
;~ $debutMot = obtientDebutMot($texte, $a)
;~ MsgBox(0,"",$m)
;~ $retCompletionMots = StringRegExp($texte, "(?i)(?:\A|[\s])(" & $debutMot & "[^\s]+)", 3)

; liste des mots qui peuvent correspondre
;~ _ArrayDisplay($retCompletionMots)

Func obtientDebutMot($txt, $trucMachinChose)
    Local $i, $temp

    For $i = 1 To StringLen($txt)
        $temp = StringMid($txt, StringLen($txt) - $i + 1, 1)
        $index = _ArraySearch($trucMachinChose, $temp)
        If $index <> -1 Then
            Return StringRight($txt, $i - 1)
        EndIf
    Next

    Return $txt
EndFunc   ;==>obtientDebutMot

;~ Exit

$Form1 = GUICreate("Form1", 500, 500)
$Edit = GUICtrlCreateEdit("", 0, 0, 500, 500)
GUISetState(@SW_SHOW)


;~ $phrases = IniReadSection("phrases.ini", "prhases")
Dim $phrases[10][2]
$phrases[0][0] = 4
$phrases[1][1] = "Bonjour"
$phrases[2][1] = "Salut"
$phrases[3][1] = "Une longue phrase avec des espace et des petits oignons !"
$phrases[4][1] = "Bonbon"

;~ _ArrayUnique($phrases,2)
;~ _ArraySort($phrases)
$modif = 1
$lettre = ""

While 1
    $nMsg = GUIGetMsg()
    Select
        Case $nMsg = $GUI_EVENT_CLOSE
            Exit
        Case _GUICtrlEdit_GetModify($Edit) = "True"
            If Not _IsPressed("08") Then
                $pos = _GUICtrlEdit_GetSel($Edit)

                ; texte du début du document jusqu'au mot
                $debutDoc_mot = StringLeft(_GUICtrlEdit_GetText($Edit), $pos[0])
;~              ConsoleWrite($debutDoc_mot)
                $debutMot = obtientDebutMot($debutDoc_mot, $a)
                ConsoleWrite($debutMot & @CRLF)
                If $debutMot Then
                    $retCompletionMots = StringRegExp(_GUICtrlEdit_GetText($Edit), _
                            "(?i)(?:\A|[\s])(" & $debutMot & "[^\s]+)", _
                            3)
                EndIf
;~ MsgBox(0,$debutMot,_GUICtrlEdit_GetText($Edit))
;~              ClipPut($debutMot)

                If UBound($retCompletionMots) Then
                    $retCompletionMots = _ArrayToString($retCompletionMots, @CRLF)
                    ToolTip($retCompletionMots, 0, 0)
                Else
                    ToolTip("")
                EndIf

                If Not StringIsAlNum(StringRight(StringLeft(_GUICtrlEdit_GetText($Edit), $pos[0] - 1), 1)) Or $modif > 1 Then
                    $lettre = StringRight(StringLeft(_GUICtrlEdit_GetText($Edit), $pos[0]), $modif)
                    For $i = 1 To $phrases[0][0] + 1
                        If $i = $phrases[0][0] + 1 Then
                            If $modif > 1 Then
                                If StringRight(StringLeft(_GUICtrlEdit_GetText($Edit), $pos[0]), 1) = " " Then
                                    _GUICtrlEdit_Undo($Edit)
                                    $pos = _GUICtrlEdit_GetSel($Edit)
                                    _GUICtrlEdit_SetSel($Edit, $pos[1], $pos[1])
                                    _GUICtrlEdit_InsertText($Edit, " ", $pos[1])
                                EndIf
                            EndIf
                            $modif = 1
                            ExitLoop
                        EndIf
                        If $lettre = StringLeft($phrases[$i][1], $modif) Then
                            _GUICtrlEdit_InsertText($Edit, StringRight($phrases[$i][1], StringLen($phrases[$i][1]) - $modif), $pos[0])
                            _GUICtrlEdit_SetSel($Edit, $pos[0], $pos[0] + StringLen($phrases[$i][1]) - $modif)
                            $modif += 1
                            ExitLoop
                        EndIf
                    Next
                EndIf
            EndIf
            _GUICtrlEdit_SetModify($Edit, "False")

    EndSelect
WEnd

Ca ne marche que sur une seule ligne pour l'instant. En tapant par exemple : "test " puis "t" alors il y a un tooltip qui s'affiche.

[Iste]

ben le petit bout que je galere, il est la juste pour remplir la base de donné de mots, apres le reste du code fait ce qu'il y a a faire (mais je sais pas pourquoi, les caratere spécieaux font tout planter :/)

Je regarde ton code ^^

Edit oula, suis fatigué, j'ai du mal a comprendre ^^' sinon j'ai upgradé mon code, apres avoir trouvé les erreur, le voici :

► Afficher le texte

Code : Tout sélectionner

#include <GuiEdit.au3>
#include <Misc.au3>
#include <GUIConstantsEx.au3>
#Include <Array.au3>

$Form1 = GUICreate("Form1", 500, 500)
$Edit = GUICtrlCreateEdit("", 0, 0, 500, 500)
GUISetState(@SW_SHOW)

Dim $phrases[5]

$phrases[0] = 4
$phrases[1] = "Bonjour"
$phrases[2] = "Salut"
$phrases[3] = "Une longue phrase avec des espace et des petits oignons !"
$phrases[4] = "Bonbon"

$modif = 1
$lettre = ""

AdlibEnable ("getmots",1000)
HotKeySet("{esc}","aff")

While 1
    
    $nMsg = GUIGetMsg()
    Select
        Case $nMsg = $GUI_EVENT_CLOSE
            Exit
        Case _GUICtrlEdit_GetModify($Edit) = "True"
            If Not _IsPressed("08") Then
                $pos = _GUICtrlEdit_GetSel($Edit)
                If Not StringIsAlNum(StringRight(StringLeft(_GUICtrlEdit_GetText($Edit), $pos[0] - 1), 1)) Or $modif > 1 Then
                    $lettre = StringRight(StringLeft(_GUICtrlEdit_GetText($Edit), $pos[0]), $modif)
                    For $i = 1 To $phrases[0] + 1
                        If $i = $phrases[0] + 1 Then
                            If $modif > 1 Then
                                If StringRight(StringLeft(_GUICtrlEdit_GetText($Edit), $pos[0]), 1) = " " Then
                                    _GUICtrlEdit_Undo($Edit)
                                    $pos = _GUICtrlEdit_GetSel($Edit)
                                    _GUICtrlEdit_SetSel($Edit, $pos[1], $pos[1])
                                    _GUICtrlEdit_InsertText($Edit, " ", $pos[1])
                                EndIf
                            EndIf
                            $modif = 1
                            ExitLoop
                        EndIf
                        If $lettre = StringLeft($phrases[$i], $modif) Then
                            _GUICtrlEdit_InsertText($Edit, StringRight($phrases[$i], StringLen($phrases[$i]) - $modif), $pos[0])
                            _GUICtrlEdit_SetSel($Edit, $pos[0], $pos[0] + StringLen($phrases[$i]) - $modif)
                            $modif += 1
                            ExitLoop
                        EndIf
                    Next
                EndIf
            EndIf
            _GUICtrlEdit_SetModify($Edit, "False")

    EndSelect
WEnd

Func getmots()
    $var = StringRegExp (_GUICtrlEdit_GetText($Edit),"([a-zA-Z0-9]+)",3)
    If Not @error Then
        _ArrayDelete($phrases,0)
;~      _ArrayConcatenate($phrases , $var)
        $phrases = $var
        $phrases = _ArrayUnique($phrases)
    EndIf
EndFunc

Func aff()
    
        _ArrayDisplay($phrases)
    
EndFunc

la fonction getmots() rajoute a la liste tout les mot présent dans le texte. la ligne $phrases = $var peut être remplacé par _ArrayConcatenate($phrases , $var), cette dernière conserve en mémoire les mot tapé puis effacé, mais ca pose un petit problème si elle mémorise un mot qui été en court d'écriture.

Vala orax, c'est bien ca que ton code fait ? car je suis un peu fatigué, j'ai du mal a tout saisir désolé ^^'

[orax]

Vala orax, c'est bien ca que ton code fait ?

Non !

[Iste]

tant mieux ! car sinon ca aurait été tordu...
Bon, Iste dodo, je reviendrais voir ca demain ^^

[orax]

► Afficher le texte

Code : Tout sélectionner

#include <GuiEdit.au3>
#include <Misc.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ListBoxConstants.au3>
#include <Array.au3>
#include <WinAPI.au3>

; constante servant à définir ce qui sépare les mots
Global Const $SEPARATEUR_DE_MOTS[5] = [ _
        @CRLF, _
        @CR, _
        @LF, _
        @TAB, _
        " "]

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

Global $Form1 = GUICreate("Form1", 500, 500)
Global $Edit = GUICtrlCreateEdit("", 0, 0, 500, 500)
Global $hEdit = GUICtrlGetHandle($Edit)
Global $liste
GUISetState(@SW_SHOW)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()

Func completion($txt, $emplacement_curseur, $separateur)
    Local $i, $temp, $debutMot, $retCompletionMots

    If Not $txt Then Return SetError(1, "", "")

    ; récupère le texte du début du document jusqu'au mot à compléter
    $debutDoc_mot = StringLeft($txt, $emplacement_curseur)

    ; recherche le début du mot
    For $i = 1 To StringLen($txt)
        $temp = StringMid($debutDoc_mot, StringLen($debutDoc_mot) - $i + 1, 1)
        $index = _ArraySearch($separateur, $temp)
        If $index <> -1 Then
            $debutMot = StringRight($debutDoc_mot, $i - 1)

            ExitLoop
        EndIf
    Next
    If Not $debutMot Then $debutMot = $txt

    ; recherche le mot dans le texte
    If $debutMot Then $retCompletionMots = StringRegExp($txt, _
            "(?i)(?:\A|[\s])(" & $debutMot & "[^\s]+)", _
            3)

    ; si le mot est trouvé
    If UBound($retCompletionMots) Then
        $retCompletionMots = _ArrayUnique($retCompletionMots)

        Return $retCompletionMots
    Else
        Return SetError(1, "", "")
    EndIf
EndFunc   ;==>completion

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam, $ilParam

    Switch $ilParam
        Case $hEdit
            Switch _WinAPI_HiWord($iwParam)
                Case $EN_CHANGE
                    $pos = _GUICtrlEdit_GetSel($Edit)

                    $retCompletionMots = completion(GUICtrlRead($Edit), $pos[0], $SEPARATEUR_DE_MOTS)

                    If UBound($retCompletionMots) Then
                        $retCompletionMots = _ArrayToString($retCompletionMots, "|", 1)
                        ToolTip($retCompletionMots, 0, 0)
                        $liste = GUICtrlCreateList("", 176, 32, 121, 97, $WS_VSCROLL)
                        GUICtrlSetData($liste, $retCompletionMots)
                    Else
                        ToolTip("")
                    EndIf
            EndSwitch
    EndSwitch
EndFunc   ;==>WM_COMMAND

[orax]

J'ai ajouté une Listebox pour la complétion (mise à jour dans mon premier message : http://www.autoitscript.fr/forum/viewto ... 217#p19217).