UDF > Date >


_TicksToTime

Convertit le nombre de cycles spécifiés en heures, minutes et secondes

#include <Date.au3>
_TicksToTime ( $iTicks, ByRef $iHours, ByRef $iMins, ByRef $iSecs )

Paramètres

$iTicks Nombre de cycles.
$iHours Variable qui contiendra les heures.
$iMins Variable qui contiendra les minutes.
$iSecs Variable qui contiendra les secondes.

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - $iTicks n'est pas un nombre entier.

En relation

_TimeToTicks

Exemple

; *** Démo pour afficher une fenêtre timer
#include <Date.au3>
#include <GUIConstantsEx.au3>

Global $g_hTimer, $g_iSecs, $g_iMins, $g_iHour, $g_sTime

Example()

Func Example()
    ; Crée la GUI
    GUICreate("Timer", 120, 50)
    GUICtrlCreateLabel("00:00:00", 10, 10)
    GUISetState(@SW_SHOW)
    ; Démarre le timer
    $g_hTimer = TimerInit()
    AdlibRegister("Timer", 50)
    Local $iMsg

    Do
        $iMsg = GUIGetMsg()
        ; FileWriteLine("debug.log",@MIN & ":" & @SEC & " ==> avant")
        If $iMsg <> $GUI_EVENT_CLOSE Then 
            ; FileWriteLine("debug.log",@MIN & ":" & @SEC & " ==> après")
        EndIf
    Until $iMsg = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

Func Timer()
    _TicksToTime(Int(TimerDiff($g_hTimer)), $g_iHour, $g_iMins, $g_iSecs)
    Local $sTime = $g_sTime ; enregistre l'heure actuelle pour être en mesure de la tester et d'éviter un scintillement...
    $g_sTime = StringFormat("%02i:%02i:%02i", $g_iHour, $g_iMins, $g_iSecs)
    If $sTime <> $g_sTime Then ControlSetText("Timer", "", "Static1", $g_sTime)
EndFunc   ;==>Timer