UDF > IE >

_IEFormGetCollection

Retourne une variable objet collection représentant les formulaires du document ou un formulaire unique donné par son index

#include <IE.au3>
_IEFormGetCollection ( ByRef $oObject [, $iIndex = -1] )

Paramètres

$oObject	Variable objet InternetExplorer.Application, Window, Frame ou objet iFrame
$iIndex	[optionnel] Spécifie s'il faut retourner une collection ou une instance indexée 0 ou un entier positif retourne une instance indexée -1 = (Par défaut) retourne une collection

Valeur de retour

Succès:	Retourne une variable objet avec une collection de tous les formulaire du document, @extended = nombre de formulaires.
Échec:	Définit @error <> 0.
@error:	3 ($_IEStatus_InvalidDataType) - Type de donnée invalide 5 ($_IEStatus_InvalidValue) - Valeur invalide 7 ($_IEStatus_NoMatch) - Pas de correspondance trouvée
@extended:	Contient le nombre de paramètres invalides

En relation

_IEFormGetObjByName, _IEFormReset, _IEFormSubmit

Exemple

Exemple 1

; Obtient une référence sur un formulaire spécifique  par index de base 0,
; dans ce cas le premier formulaire de la page

#include <IE.au3>

Local $oIE = _IECreate("http://www.google.com")
Local $oForm = _IEFormGetCollection($oIE, 0)
Local $oQuery = _IEFormElementGetCollection($oForm, 4)
_IEFormElementSetValue($oQuery, "AutoIt IE.au3")
_IEFormSubmit($oForm)

Exemple 2

; Obtient une référence sur la collection de formulaires de la page,
; puis boucle dans la collection pour afficher des informations sur chaque formulaire

#include <IE.au3>
#include <MsgBoxConstants.au3>

Local $oIE = _IECreate("http://www.autoitscript.com")
Local $oForms = _IEFormGetCollection($oIE)
MsgBox($MB_SYSTEMMODAL, "Forms Info", "There are " & @extended & " form(s) on this page")
For $oForm In $oForms
    MsgBox($MB_SYSTEMMODAL, "Form Info", $oForm.name)
Next

Exemple 3

; Obtient une référence sur la collection de formulaires d'une page,
; puis boucle dans la collection pour afficher des  informations sur chaque formulaire
; en montrant l'utilisation de l'index des formulaires

#include <IE.au3>
#include <MsgBoxConstants.au3>

Local $oIE = _IECreate("http://www.autoitscript.com")
Local $oForms = _IEFormGetCollection($oIE)
Local $iNumForms = @extended
MsgBox($MB_SYSTEMMODAL, "Forms Info", "There are " & $iNumForms & " forms on this page")
Local $oForm
For $i = 0 To $iNumForms - 1
    $oForm = _IEFormGetCollection($oIE, $i)
    MsgBox($MB_SYSTEMMODAL, "Form Info", $oForm.name)
Next