UDF > IE >

_IEFormElementOptionSelect

Définit la valeur d'un élément donné de formulaire

#include <IE.au3>
_IEFormElementOptionSelect ( ByRef $oObject, $sString [, $iSelect = 1 [, $sMode = "byValue" [, $iFireEvent = 1]]] )

Paramètres

$oObject Objet Form Element de type "Select Option"
$sString Valeur utilisée pour déterminer l'élément - traitement selon $sMode
$iSelect [optionnel] Spécifie si l'élément doit être activé ou désactivé
    -1 = Retourne l'état de la sélection
    0 = Sélectionne l'élément
    1 = (par défaut) Désélectionne l'élément
$sMode [optionnel] Spécifie le mode de recherche:
    "byValue" = (par défaut) de l'option que vous souhaitez sélectionner
    "byText" = texte de l'option que vous souhaitez sélectionner
    "byIndex" = index, à prtir de 0 de l'option que vous souhaitez sélectionner
$iFireEvent [optionnel] Indique si il faut déclencher les événements OnChange et OnClick après avoir changé la valeur
    0 = ne pas déclencher les événements OnChange ou OnClick cas après avoir changé la valeur
    1 = (par défaut) Déclencher les événements OnChange et OnClick après avoir changé la valeur

Valeur de retour

Succès: Retourne l'état actuellement sélectionné si $iSélecteur = -1, sinon retourne 1.
Échec: Retourne 0 et définit @error <> 0.
@error: 3 ($_IEStatus_InvalidDataType) - Type de donnée invalide
4 ($_IEStatus_InvalidObjectType) - Type d'objet invalide
5 ($_IEStatus_InvalidValue) - Valeur invalide
7 ($_IEStatus_NoMatch) - Pas de correspondance trouvée
@extended: Contient le nombre de paramètres invalides

Remarque

Le paramètre $iFireEvent est significatif seulement si l'élément de formulaire a un événement onChange associé.

En relation

_IEFormElementCheckBoxSelect, _IEFormElementGetValue, _IEFormElementRadioSelect, _IEFormElementSetValue

Exemple

Exemple 1

; Ouvre un navigateur avec l'exemple de formulaire, obtient une référence sur le formulaire, obtient une référence
; sur l'élément sélectionné, recommence 10 fois la sélection des options byValue, byText et byIndex

#include <IE.au3>

Local $oIE = _IE_Example("form")
Local $oForm = _IEFormGetObjByName($oIE, "ExampleForm")
Local $oSelect = _IEFormElementGetObjByName($oForm, "selectExample")
_IEAction($oSelect, "focus")
For $i = 1 To 10
    _IEFormElementOptionSelect($oSelect, "Freepage", 1, "byText")
    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, "midipage.html", 1, "byValue")
    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, 0, 1, "byIndex")
    Sleep(1000)
Next

_IEQuit($oIE)

Exemple 2

; Ouvre un navigateur avec l'exemple de formulaire, obtient une référence sur le formulaire, obtient une référence
; sur plusieurs éléments sélectionnés, recommence 5 fois la sélection puis annule
; les options byValue, byText et byIndex.

#include <IE.au3>

Local $oIE = _IE_Example("form")
Local $oForm = _IEFormGetObjByName($oIE, "ExampleForm")
Local $oSelect = _IEFormElementGetObjByName($oForm, "multipleSelectExample")
_IEAction($oSelect, "focus")
For $i = 1 To 3
    _IEFormElementOptionSelect($oSelect, "Carlos", 1, "byText")
    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, "Name2", 1, "byValue")
    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, 5, 1, "byIndex")
    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, "Carlos", 0, "byText")
    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, "Name2", 0, "byValue")
    Sleep(1000)
    _IEFormElementOptionSelect($oSelect, 5, 0, "byIndex")
    Sleep(1000)
Next

_IEQuit($oIE)

Exemple 3

; Ouvre un navigateur avec l'exemple de formulaire, obtient une référence sur le formulaire, obtient une référence
; sur l'élément sélectionné, regarde si l'option "Freepage" est sélectionné et
; affiche le résultat.  Répète pour l'option avec index 0 et pour l'option
; avec valeur 'midipage.html'

#include <IE.au3>
#include <MsgBoxConstants.au3>

Local $oIE = _IE_Example("form")
Local $oForm = _IEFormGetObjByName($oIE, "ExampleForm")
Local $oSelect = _IEFormElementGetObjByName($oForm, "selectExample")
If _IEFormElementOptionSelect($oSelect, "Freepage", -1, "byText") Then
    MsgBox($MB_SYSTEMMODAL, "Option Selected", "Option Freepage is selected")
Else
    MsgBox($MB_SYSTEMMODAL, "Option Selected", "Option Freepage is Not selected")
EndIf
If _IEFormElementOptionSelect($oSelect, 0, -1, "byIndex") Then
    MsgBox($MB_SYSTEMMODAL, "Option Selected", "The First (index 0) option is selected")
Else
    MsgBox($MB_SYSTEMMODAL, "Option Selected", "The First (index 0) option is Not selected")
EndIf
If _IEFormElementOptionSelect($oSelect, "midipage.html", -1, "byValue") Then
    MsgBox($MB_SYSTEMMODAL, "Option Selected", "The option with value 'midipage.html' is selected")
Else
    MsgBox($MB_SYSTEMMODAL, "Option Selected", "The option with value 'midipage.html' is NOT selected")
EndIf

_IEQuit($oIE)