UDF > GUI > GuiTreeView >


_GUICtrlTreeView_SetIcon

Définit une icône pour le noeud

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetIcon ( $hWnd [, $hItem = 0 [, $sIconFile = "" [, $iIconID = 0 [, $iImageMode = 6]]]] )

Paramètres

$hWnd ID/handle du contrôle
$hItem [optionnel] ID/handle du noeud
$sIconFile [optionnel] Le fichier d'où extraire l'icône de
$iIconID [optionnel] L'ID de l'icône à extraire du fichier
$iImageMode [optionnel] 2=image normale / 4=image de sélection

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $aidItem[10], $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)

    GUICreate("TreeView Set Icon", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To 9
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
        _GUICtrlTreeView_SetIcon($idTreeView, $aidItem[$x], "shell32.dll", 3)
        For $y = 1 To 3
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $aidItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    _GUICtrlTreeView_SetIcon($idTreeView, $aidItem[0], "shell32.dll", 4)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example