UDF > GUI > GuiTreeView >

_GUICtrlTreeView_GetTree

Retourne le chemin formé des noeuds et de leur texte, pour atteindre un noeud spécifié

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetTree ( $hWnd [, $hItem = 0] )

Paramètres

$hWnd ID/handle du contrôle
$hItem ID/handle du noeud

Valeur de retour

Succès: Retourne le chemin du noeud, dans l'arbre.
Échec: Retourne une chaîne vide.

Remarque

Utilisez Opt("GUIDataSeparatorChar", param) pour changer le caractère séparateur utilisé.
Si $hItem est 0, alors le noeud sélectionné est utilisé.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Global $g_hImage, $g_hStateImage

Example()

Func Example()
    Local $ahItem[10], $aidChildItem[30], $iYItem = 0, $iRand, $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)

    Opt("GUIDataSeparatorChar", "\")

    GUICreate("TreeView Get Tree", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _CreateNormalImageList()
    _GUICtrlTreeView_SetNormalImageList($idTreeView, $g_hImage)

    _CreateStateImageList()
    _GUICtrlTreeView_SetStateImageList($idTreeView, $g_hStateImage)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To 9
        $ahItem[$x] = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x), 4, 5)
        _GUICtrlTreeView_SetStateImageIndex($idTreeView, $ahItem[$x], 1)
        For $y = 1 To 3
            $aidChildItem[$iYItem] = _GUICtrlTreeView_AddChild($idTreeView, $ahItem[$x], StringFormat("[%02d] New Child", $y), 0, 3)
            _GUICtrlTreeView_SetStateImageIndex($idTreeView, $aidChildItem[$iYItem], 1)
            $iYItem += 1
        Next
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    _GUICtrlTreeView_SelectItem($idTreeView, $ahItem[0])
    _GUICtrlTreeView_SetStateImageIndex($idTreeView, $ahItem[0], 2)

    MsgBox($MB_SYSTEMMODAL, "Information", "Tree for Child Index 2: " & _GUICtrlTreeView_GetTree($idTreeView, $aidChildItem[2]))
    _GUICtrlTreeView_SelectItem($idTreeView, $aidChildItem[2])

    $iRand = Random(0, 29, 1)
    _GUICtrlTreeView_SelectItem($idTreeView, $aidChildItem[$iRand])
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Tree for Child Selected Index %d: %s", $iRand, _GUICtrlTreeView_GetTree($idTreeView)))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

Func _CreateNormalImageList()
    $g_hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($g_hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($g_hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($g_hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($g_hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($g_hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($g_hImage, "shell32.dll", 146)
EndFunc   ;==>_CreateNormalImageList

Func _CreateStateImageList()
    $g_hStateImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($g_hStateImage, "shell32.dll", 3)
    _GUIImageList_AddIcon($g_hStateImage, "shell32.dll", 4)
EndFunc   ;==>_CreateStateImageList