UDF > GUI > GuiTab >

_GUICtrlTab_HitTest

Détermine si un point est dans un contrôle à onglet

#include <GuiTab.au3>
_GUICtrlTab_HitTest ( $hWnd, $iX, $iY )

Paramètres

$hWnd ID/handle du contrôle Tab
$iX Abscisse X du point à tester
$iY Ordonnée Y du point à tester

Valeur de retour

Retourne un tableau avec le format suivant:
    [0] - Index, de base 0, de l'onglet, ou -1 si aucun onglet est à la position
    [1] - Résultats d'un test réussi:
        1 - La position n'est pas sur un onglet
        2 - La position est sur l'icône d'un onglet
        4 - La position est sur le texte d'un onglet

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $aHit, $idTab

    ; Crée une GUI
    GUICreate("Tab Control HitTest", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Ajoute des onglets
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

    ; Fait un test de positionnement
    $aHit = _GUICtrlTab_HitTest($idTab, 80, 10)
    MsgBox($MB_SYSTEMMODAL, "Information", "Point [80,10] is over tab " & $aHit[0])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example