UDF > GUI > GuiTab >

_GUICtrlTab_GetItemState

Obtient l'état d'un onglet

#include <GuiTab.au3>
_GUICtrlTab_GetItemState ( $hWnd, $iIndex )

Paramètres

$hWnd ID/handle du contrôle Tab
$iIndex Index, de base 0, de l'onglet

Valeur de retour

Retourne un Integer avec les états des onglets suivants:
    $TCIS_BUTTONPRESSED - L'onglet est sélectionné
    $TCIS_HIGHLIGHTED - L'onglet est en surbrillance

En relation

_GUICtrlTab_SetItemState

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idTab

    ; Crée une GUI
    GUICreate("Tab Control Get Item State", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296, $TCS_BUTTONS)
    GUISetState(@SW_SHOW)

    ; Ajoute des onglets
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

    ; Obtient/Définit l'état de tab 2
    _GUICtrlTab_SetItemState($idTab, 1, $TCIS_BUTTONPRESSED)
    MsgBox($MB_SYSTEMMODAL, "Information", "Tab 2 state: " & _ExplainItemState(_GUICtrlTab_GetItemState($idTab, 1)))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

Func _ExplainItemState($iState)
    Local $sText = ""
    If $iState = 0 Then $sText &= "No state set on this item" & @CRLF
    If BitAND($iState, $TCIS_BUTTONPRESSED) Then $sText &= "Button Pressed" & @CRLF
    If BitAND($iState, $TCIS_HIGHLIGHTED) Then $sText &= "Button Highlighted"
    Return $sText
EndFunc   ;==>_ExplainItemState