UDF > GUI > GuiStatusBar >

_GUICtrlStatusBar_GetRect

Obtient, dans un tableau, le rectangle englobant une partie

#include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetRect ( $hWnd, $iPart )

Paramètres

$hWnd Handle du contrôle StatusBar
$iPart Index, de base 0, de la partie

Valeur de retour

Succès: Retourne un tableau avec le format suivant:
    $aRect[0] = Coordonnée X du coin supérieur gauche du rectangle
    $aRect[1] = Coordonnée Y du coin supérieur gauche du rectangle
    $aRect[2] = Coordonnée X du coin inférieur droit du rectangle
    $aRect[3] = Coordonnée Y du coin inférieur droit du rectangle
Échec: Définit @error <> 0.

En relation

_GUICtrlStatusBar_GetRectEx

Exemple

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $aRect, $hStatus
    Local $aParts[3] = [75, 150, -1]

    ; Crée une GUI
    $hGUI = GUICreate("StatusBar Get Rect", 400, 300)
    $hStatus = _GUICtrlStatusBar_Create($hGUI)

    ; Crée un contrôle memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Définit/Obtient des parties
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)

    ; Obtient le rectangle de la partie 1 
    $aRect = _GUICtrlStatusBar_GetRect($hStatus, 0)
    MemoWrite("Part 1 left ...: " & $aRect[0])
    MemoWrite("Part 1 top ....: " & $aRect[1])
    MemoWrite("Part 1 right ..: " & $aRect[2])
    MemoWrite("Part 1 bottom .: " & $aRect[3])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite