UDF > GUI > GuiMenu >

_GUICtrlMenu_SetItemBitmaps

Associe le bitmap spécifié à un élément spécifié de menu

#include <GuiMenu.au3>
_GUICtrlMenu_SetItemBitmaps ( $hMenu, $iItem, $hChecked, $hUnChecked [, $bByPos = True] )

Paramètres

$hMenu Handle du contrôle Menu
$iItem Identifiant ou position de l'élément de menu
$hChecked Handle du bitmap qui doit s'afficher lorsque l'élément de menu est sélectionné
$hUnChecked Handle du bitmap qui doit s'afficher lorsque l'élément de menu n'est pas sélectionné
$bByPos [optionnel] Indicateur d'identifiant de menu:
    True  - $iItem est une position de base 0 de l'élément
    False - $iItem est un identifiant d'élément de menu

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Si le paramètre $hUnchecked $u $hChecked est 0, le système n'affiche rien à côté de l'élément de menu que son état soit coché ou décoché.
Si les deux paramètres sont à 0, le système affiche le bitmap coché par défaut lorsque l'élément est sélectionné, et supprime le bitmap lorsque l'élément n'est pas sélectionné.

En relation

_GUICtrlMenu_SetItemBmpChecked, _GUICtrlMenu_SetItemBmpUnchecked

Voir aussi

Consultez SetMenuItemBitmaps dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>
#include <WinAPIGdi.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain, $hBmp1, $hBmp2
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout

    ; Crée une GUI
    $hGUI = GUICreate("Menu", 400, 300)

    ; Crée un menu File
    $hFile = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hFile, 0, "&New", $e_idNew)
    _GUICtrlMenu_InsertMenuItem($hFile, 1, "&Open", $e_idOpen)
    _GUICtrlMenu_InsertMenuItem($hFile, 2, "&Save", $e_idSave)
    _GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem($hFile, 4, "E&xit", $e_idExit)

    ; Crée un menu Edit
    $hEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hEdit, 0, "&Cut", $e_idCut)
    _GUICtrlMenu_InsertMenuItem($hEdit, 1, "C&opy", $e_idCopy)
    _GUICtrlMenu_InsertMenuItem($hEdit, 2, "&Paste", $e_idPaste)

    ; Crée un menu Help
    $hHelp = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hHelp, 0, "&About", $e_idAbout)

    ; Crée un menu Main
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hMain, 0, "&File", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem($hMain, 1, "&Edit", 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem($hMain, 2, "&Help", 0, $hHelp)

    ; Attache le menu à la fenêtre
    _GUICtrlMenu_SetMenu($hGUI, $hMain)

    ; Crée un contrôle mémo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 276, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Définit les bitmaps coché/décoché du menu File
    $hBmp1 = _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 11, 11)
    $hBmp2 = _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 11, 11)
    _GUICtrlMenu_SetItemBitmaps($hFile, 0, $hBmp1, $hBmp2)
    _GUICtrlMenu_SetItemBitmaps($hFile, 1, $hBmp1, $hBmp2)
    _GUICtrlMenu_SetItemBitmaps($hFile, 2, $hBmp1, $hBmp2)

    ; Vérifie l'élément de menu Open
    _GUICtrlMenu_CheckMenuItem($hFile, 1)

    ; Montre que les handles de bitmaps correspondent
    MemoWrite("Checked handle ......: 0x" & Hex($hBmp1))
    MemoWrite("Unchecked handle ....: 0x" & Hex($hBmp2))
    MemoWrite("Open checked handle .: 0x" & Hex(_GUICtrlMenu_GetItemBmpChecked($hFile, 0)))
    MemoWrite("Open unchecked handle: 0x" & Hex(_GUICtrlMenu_GetItemBmpUnchecked($hFile, 0)))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite