UDF > GUI > GuiMenu >


_GUICtrlMenu_AddMenuItem

Ajoute un nouvel élément de menu à la fin d'un menu

#include <GuiMenu.au3>
_GUICtrlMenu_AddMenuItem ( $hMenu, $sText [, $iCmdID = 0 [, $hSubMenu = 0]] )

Paramètres

$hMenu Handle du contrôle Menu
$sText Texte de l'élément. Si vide, un trait de séparation sera ajouté au menu.
$iCmdID [optionnel] ID de commande à attribuer à l'élément
$hSubMenu [optionnel] Handle du sous-menu associé à l'élément de menu

Valeur de retour

Succès: Retourne l'index de l'élément de menu, de base 0.
Échec: Retourne -1.

En relation

_GUICtrlMenu_InsertMenuItem

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>

Example()

Func Example()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout

    ; Crée une GUI
    $hGUI = GUICreate("Menu", 400, 300)

    ; Crée un menu File
    $hFile = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_AddMenuItem($hFile, "&New", $e_idNew)
    _GUICtrlMenu_AddMenuItem($hFile, "&Open", $e_idOpen)
    _GUICtrlMenu_AddMenuItem($hFile, "&Save", $e_idSave)
    _GUICtrlMenu_AddMenuItem($hFile, "", 0)
    _GUICtrlMenu_AddMenuItem($hFile, "E&xit", $e_idExit)

    ; Crée un menu Edit
    $hEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_AddMenuItem($hEdit, "&Cut", $e_idCut)
    _GUICtrlMenu_AddMenuItem($hEdit, "C&opy", $e_idCopy)
    _GUICtrlMenu_AddMenuItem($hEdit, "&Paste", $e_idPaste)

    ; Crée un menu Help
    $hHelp = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_AddMenuItem($hHelp, "&About", $e_idAbout)

    ; Crée un menu Main
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_AddMenuItem($hMain, "&File", 0, $hFile)
    _GUICtrlMenu_AddMenuItem($hMain, "&Edit", 0, $hEdit)
    _GUICtrlMenu_AddMenuItem($hMain, "&Help", 0, $hHelp)

    ; Attache le menu à la fenêtre
    _GUICtrlMenu_SetMenu($hGUI, $hMain)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example