#include <ColorConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Set Text BkColor", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Définit les couleurs
    _GUICtrlListView_SetBkColor($idListview, $CLR_MONEYGREEN)
    _GUICtrlListView_SetTextColor($idListview, $CLR_BLACK)
    _GUICtrlListView_SetTextBkColor($idListview, $CLR_MONEYGREEN)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Ajoute des éléments
    _GUICtrlListView_BeginUpdate($idListview)
    For $iI = 1 To 10
        _GUICtrlListView_AddItem($idListview, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($idListview)

    ; affiche les couleurs
    MsgBox($MB_SYSTEMMODAL, "Information", "Back Color ....: " & _GUICtrlListView_GetBkColor($idListview) & @CRLF & _
            "Text Color ....: " & _GUICtrlListView_GetTextColor($idListview) & @CRLF & _
            "Text Back Color: " & _GUICtrlListView_GetTextBkColor($idListview))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example