UDF > GUI > GuiListView >


_GUICtrlListView_SetItemChecked

Définit l'état coché/décoché du contrôle

#include <GuiListView.au3>
_GUICtrlListView_SetItemChecked ( $hWnd, $iIndex [, $bCheck = True] )

Paramètres

$hWnd ID/handle du contrôle
$iIndex Index, de base 0 de l'élément, -1 définit tous les éléments
$bCheck [optionnel] Valeur pour définir l'état coché/décoché:
    True - Coché
    False - Décoché

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Utilisez cette fonction uniquement pour des contrôles qui ont le style étendu $LVS_EX_CHECKBOXES.

En relation

_GUICtrlListView_GetItemChecked

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $iStylesEx = BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES), $idListview

    GUICreate("ListView Set Item Checked State", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    _GUICtrlListView_SetExtendedListViewStyle($idListview, $iStylesEx)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddItem($idListview, "Row 3: Col 1", 2)

    ; Coche l'item 2
    _GUICtrlListView_SetItemChecked($idListview, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", "Item 2 Checked: " & _GUICtrlListView_GetItemChecked($idListview, 1))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example