UDF > GUI > GuiListView >

_GUICtrlListView_SetColumn

Définit les attributs d'une colonne

#include <GuiListView.au3>
_GUICtrlListView_SetColumn ( $hWnd, $iIndex, $sText [, $iWidth = -1 [, $iAlign = -1 [, $iImage = -1 [, $bOnRight = False]]]] )

Paramètres

$hWnd ID/handle du contrôle
$iIndex Index de la colonne, de base 0
$sText Texte de l'en-tête de colonne
$iWidth [optionnel] Largeur de la colonne, en pixels
$iAlign [optionnel] Alignement de l'en-tête de colonne et du texte du sous-élément de la colonne:
    0 - Le texte est aligné à gauche
    1 - Le texte est aligné à droite
    2 - Le texte est centré
$iImage [optionnel] Index, de base 0, d'une image de la liste d'images
$bOnRight [optionnel] Si True, l'image de la colonne apparaît à droite du texte

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlListView_GetColumn, _GUICtrlListView_JustifyColumn

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $aInfo, $idListview

    GUICreate("ListView Set Column", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Modifie une colonne
    $aInfo = _GUICtrlListView_GetColumn($idListview, 0)
    MsgBox($MB_SYSTEMMODAL, "Information", "Column 1 Width: " & $aInfo[4])
    _GUICtrlListView_SetColumn($idListview, 0, "New Column 1", 150, 1)
    $aInfo = _GUICtrlListView_GetColumn($idListview, 0)
    MsgBox($MB_SYSTEMMODAL, "Information", "Column 1 Width: " & $aInfo[4])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example