UDF > GUI > GuiListView >

_GUICtrlListView_Scroll

Fait défiler le contenu d'une ListView

#include <GuiListView.au3>
_GUICtrlListView_Scroll ( $hWnd, $iDX, $iDY )

Paramètres

$hWnd ID/handle du contrôle
$iDX Valeur de type int qui indique l'ampleur du défilement horizontal en pixels.
Si le contrôle ListView est en mode d'affichage Liste, cette valeur spécifie le nombre de colonnes à faire défiler.
$iDY Valeur de type int qui indique l'ampleur du défilement vertical en pixels

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Lorsque le contrôle ListView est en mode d'affichage Rapport, le contrôle ne peut faire défiler verticalement que par pas de ligne entière.
Par conséquent, le paramètre $iDY sera arrondi au nombre le plus proche de pixels qui forme un incrément de ligne entière.
Par exemple, si la hauteur d'une ligne est de 16 pixels et si la valeur 8 est passé à $iDY, la liste défile de 16 pixels (1 ligne).
Si 7 est passé à $iDY, la liste défile de 0 pixel (0 ligne).

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Scroll", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute une colonne
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Ajoute des éléments
    _GUICtrlListView_BeginUpdate($idListview)
    For $iI = 1 To 100
        _GUICtrlListView_AddItem($idListview, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($idListview)

    ; Défile le contrôle de 500 pixels
    _GUICtrlListView_Scroll($idListview, 0, 500)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example