UDF > GUI > GuiListView >

_GUICtrlListView_RedrawItems

Force le contrôle à redessiner une séquence d'éléments

#include <GuiListView.au3>
_GUICtrlListView_RedrawItems ( $hWnd, $iFirst, $iLast )

Paramètres

$hWnd ID/handle du contrôle
$iFirst Index du premier élément à redessiner, de base 0
$iLast Index du dernier élément à redessiner, de base 0

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Les éléments spécifiés ne sont pas réellement redessinés avant que le contrôle ne reçoive un message $WM_PAINT pour les repeindre.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Redraw Items", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute une colonne
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Ajoute des éléments
    _GUICtrlListView_BeginUpdate($idListview)
    For $iI = 1 To 10
        _GUICtrlListView_AddItem($idListview, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($idListview)

    ; Redessine des éléments
    _GUICtrlListView_RedrawItems($idListview, 0, 9)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example