UDF > GUI > GuiListView >

_GUICtrlListView_GetSubItemRect

Obtient des informations sur le rectangle délimitant un élément

#include <GuiListView.au3>
_GUICtrlListView_GetSubItemRect ( $hWnd, $iIndex, $iSubItem [, $iPart = 0] )

Paramètres

$hWnd ID/handle du contrôle
$iIndex Index de l'élément parent du sous-élément, de base 0
$iSubItem Index du sous-élément, de base 1
$iPart [optionnel] La partie du sous-élément à récupérer:
    0 - Le rectangle du sous-élément entier, y compris l'icône et l'étiquette
    1 - Le rectangle de l'icône ou de la petite icône

Valeur de retour

Retourne un tableau avec le format suivant:
    [0] - Coordonnée X du coin supérieur gauche du rectangle
    [1] - Coordonnée Y du coin supérieur gauche du rectangle,
    [2] - Coordonnée X du coin inférieur droit du rectangle
    [3] - Coordonnée Y du coin inférieur droit du rectangle

Remarque

Cette fonction est utilisée uniquement avec des contrôles qui utilisent le style $LVS_REPORT.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $aRect, $idListview

    GUICreate("ListView Get SubItem Rect", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 1")
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 1")
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddItem($idListview, "Row 3: Col 1")

    ; Affiche le rectangle délimitant le sous-élément de l'élément 2
    $aRect = _GUICtrlListView_GetSubItemRect($idListview, 1, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Subitem Rectangle : [%d, %d, %d, %d]", $aRect[0], $aRect[1], $aRect[2], $aRect[3]))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example