UDF > GUI > GuiListView >

_GUICtrlListView_FindText

Recherche un élément contenant le texte spécifié

#include <GuiListView.au3>
_GUICtrlListView_FindText ( $hWnd, $sText [, $iStart = -1 [, $bPartialOK = True [, $bWrapOK = True]]] )

Paramètres

$hWnd ID/handle du contrôle
$sText Texte à rechercher
$iStart [optionnel] Index de l'élément, de base 0, à partir duquel lancer la recherche ou -1 pour commencer depuis le début.
L'élément spécifié est lui-même exclu de la recherche.
$bPartialOK [optionnel] Si True, une correspondance se produira si le texte de l'élément commence par le texte à rechercher
$bWrapOK [optionnel] Si True, la recherche se poursuivra avec le premier élément si aucune correspondance n'est trouvée

Valeur de retour

Succès: Retourne l'index de l'élément, de base 0.
Échec: Retourne -1.

Remarque

La recherche est insensible à la casse. La recherche est effectuée sur les éléments seulement.
Utilisez _GUICtrlListView_FindInText() si vous souhaitez rechercher le texte dans les sous-éléments.

En relation

_GUICtrlListView_FindInText

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $iI, $idListview

    ; Crée une GUI
    GUICreate("ListView Find Text", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Ajoute des éléments
    _GUICtrlListView_BeginUpdate($idListview)
    For $iI = 1 To 49
        _GUICtrlListView_AddItem($idListview, "Item " & $iI)
    Next
    _GUICtrlListView_AddItem($idListview, "Target item")
    For $iI = 51 To 100
        _GUICtrlListView_AddItem($idListview, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($idListview)

    ; Cherche l'élément avec 'target'
    $iI = _GUICtrlListView_FindText($idListview, "tArGeT")
    MsgBox($MB_SYSTEMMODAL, "Information", "Target Item Index: " & $iI)
    _GUICtrlListView_EnsureVisible($idListview, $iI)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example