UDF > GUI > GuiHeader >

_GUICtrlHeader_SetItemFormat

Définit le format d'un élément

#include <GuiHeader.au3>
_GUICtrlHeader_SetItemFormat ( $hWnd, $iIndex, $iFormat )

Paramètres

$hWnd Handle du contrôle
$iIndex Index de l'élément, compté à partir de 0
$iFormat Combinaison des identificateurs de format suivants:
    $HDF_CENTER - Le contenu de l'élément est centré
    $HDF_LEFT - le contenu de l'élément est aligné à gauche
    $HDF_RIGHT - Le contenu de l'élément est aligné à droite
    $HDF_BITMAP - L'élément affiche une image bitmap
    $HDF_BITMAP_ON_RIGHT - Le bitmap apparaît à droite du texte
    $HDF_OWNERDRAW - Le propriétaire du contrôle Header dessine l'élément
    $HDF_STRING - L'élément affiche une chaîne
    $HDF_IMAGE - Affiche une image à partir d'une liste d'images
    $HDF_RTLREADING - Le texte sera lu dans la direction opposée par rapport au texte de la fenêtre parent
    $HDF_SORTDOWN - Dessine une flèche vers le bas sur cet élément
    $HDF_SORTUP - Dessine une flèche vers le haut sur cet élément

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlHeader_GetItemFormat

Exemple

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>
#include <GuiImageList.au3>
#include <WinAPIGdi.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hHeader, $hImage

    ; Crée une GUI
    $hGUI = GUICreate("Header", 400, 300)
    $hHeader = _GUICtrlHeader_Create($hGUI)
    _GUICtrlHeader_SetUnicodeFormat($hHeader, True)
    $g_idMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Crée une liste d'images avec des images
    $hImage = _GUIImageList_Create(11, 11)
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 11, 11))
    _GUICtrlHeader_SetImageList($hHeader, $hImage)

    ; Ajoute des colonnes
    _GUICtrlHeader_AddItem($hHeader, "Column 1", 100, 0, 0)
    _GUICtrlHeader_AddItem($hHeader, "Column 2", 100, 0, 1)
    _GUICtrlHeader_AddItem($hHeader, "Column 3", 100, 0, 2)
    _GUICtrlHeader_AddItem($hHeader, "Column 4", 100)

    ; Définit le format de la colonne 1
    _GUICtrlHeader_SetItemFormat($hHeader, 0, BitOR($HDF_CENTER, $HDF_STRING))

    ; Montre le format de la colonne 1
    MemoWrite("Column 1 format: " & "0x" & Hex(_GUICtrlHeader_GetItemFormat($hHeader, 0)))

    Sleep(1000)

    ; Définit le format de la colonne 1
    _GUICtrlHeader_SetItemFormat($hHeader, 0, BitOR($HDF_LEFT, $HDF_STRING, $HDF_IMAGE))

    ; Montre le format de la colonne 1
    MemoWrite("Column 1 format: " & "0x" & Hex(_GUICtrlHeader_GetItemFormat($hHeader, 0)))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite