UDF > GUI > GuiEdit >

_GUICtrlEdit_Scroll

Fait défiler le texte verticalement

#include <GuiEdit.au3>
_GUICtrlEdit_Scroll ( $hWnd, $iDirection )

Paramètres

$hWnd ID/handle du contrôle
$iDirection Ce paramètre peut prendre l'une des valeurs suivantes:
    $SB_LINEDOWN - Fait défiler vers le bas d'une ligne
    $SB_LINEUP - Fait défiler vers le haut d'une ligne
    $SB_PAGEDOWN - Fait défiler vers la bas d'une page
    $SB_PAGEUP - Fait défiler vers le haut d'une page
    $SB_SCROLLCARET - Fait défiler le curseur dans la partie visible

Valeur de retour

Succès: Retourne un dword dont le mot de poids fort est 1 et.
le mot de poids faible est le nombre de lignes qui ont défilées.
Échec: Retourne 0.

Remarque

$SB_xxxxx nécessite #include <ScrollBarsConstants.au3>

En relation

_GUICtrlEdit_LineScroll

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <MsgBoxConstants.au3>
#include <ScrollBarsConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $idEdit, $sText, $iLen

    ; Crée une GUI
    GUICreate("Edit Scroll", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    GUISetState(@SW_SHOW)

    ; Définit le texte
    For $i = 1 To 50
        $sText &= $i & @CRLF
    Next
    _GUICtrlEdit_SetText($idEdit, $sText)

    MsgBox($MB_SYSTEMMODAL, "Information", "Scroll Line Down")
    _GUICtrlEdit_Scroll($idEdit, $SB_LINEDOWN)

    MsgBox($MB_SYSTEMMODAL, "Information", "Scroll Line Up")
    _GUICtrlEdit_Scroll($idEdit, $SB_LINEUP)

    MsgBox($MB_SYSTEMMODAL, "Information", "Scroll Page Down")
    _GUICtrlEdit_Scroll($idEdit, $SB_PAGEDOWN)

    MsgBox($MB_SYSTEMMODAL, "Information", "Scroll Page Up")
    _GUICtrlEdit_Scroll($idEdit, $SB_PAGEUP)

    $iLen = _GUICtrlEdit_GetTextLen($idEdit)
    _GUICtrlEdit_SetSel($idEdit, $iLen, $iLen)

    MsgBox($MB_SYSTEMMODAL, "Information", "Scroll Caret")
    _GUICtrlEdit_Scroll($idEdit, $SB_SCROLLCARET)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example