UDF > GUI > GuiButton >

_GUICtrlButton_Enable

Active ou désactive la souris et le clavier sur le bouton spécifié

#include <GuiButton.au3>
_GUICtrlButton_Enable ( $hWnd [, $bEnable = True] )

Paramètres

$hWnd ID/handle du contrôle
$bEnable [optionnel] Spécifie s'il faut activer ou désactiver le bouton:
    True - Le bouton est activé
    False - Le bouton est désactivé

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Exemple

#include <GuiButton.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $idRdo, $idRdo2, $idChk

    GUICreate("Buttons", 400, 400)
    $g_idMemo = GUICtrlCreateEdit("", 119, 10, 276, 374, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")

    $idRdo = GUICtrlCreateRadio("Radio1", 10, 10, 90, 50)

    $idRdo2 = GUICtrlCreateRadio("Radio2", 10, 60, 90, 50)
    _GUICtrlButton_SetCheck($idRdo2)

    $idChk = GUICtrlCreateCheckbox("Check1", 10, 120, 90, 50, BitOR($BS_AUTO3STATE, $BS_NOTIFY))
    _GUICtrlButton_SetCheck($idChk, $BST_INDETERMINATE)

    GUISetState(@SW_SHOW)

    MemoWrite("Disabled Button: " & _GUICtrlButton_Enable($idRdo2, False))
    Sleep(1000)
    MemoWrite("Enabled Button: " & _GUICtrlButton_Enable($idRdo2))

    Local $iMsg
    Do
        $iMsg = GUIGetMsg()
        Switch $iMsg
            Case $idRdo
                MemoWrite("Clicked $idRdo")
            Case $idRdo2
                MemoWrite("Clicked $idRdo2")
            Case $idChk
                MemoWrite("Clicked $idChk")
        EndSwitch
    Until $iMsg = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite