UDF > Excel >


_Excel_Print

Imprime un classeur, une feuille de calcul, un graphique ou une plage

#include <Excel.au3>
_Excel_Print ( $oExcel, $vObject [, $iCopies = Default [, $sPrinter = Default [, $bPreview = Default [, $iFrom = Default [, $iTo = Default [, $bPrintToFile = Default [, $bCollate = Default [, $sPrToFileName = ""]]]]]]]] )

Paramètres

$oExcel Objet application Excel
$vObject Classeur, feuille de calcul, graphique ou objet plage à imprimer. Plage peut être spécifiée au format $xlA1
$iCopies [optionnel] Nombre de copies à imprimer (valeur par défaut = mot-clé Default = 1)
$sPrinter [optionnel] Nom de l'imprimante à utiliser. Par défaut, l'imprimante active (par défaut = mot-clé Default )
$bPreview [optionnel] True pour invoquer l'aperçu avant l'impression (par défaut = mot-clé Default = False )
$iFrom [optionnel] Numéro de page où commencer l'impression (par défaut = mot-clé Default = première page)
$iTo [optionnel] Numéro de page où arrêter l'impression (par défaut = mot-clé Defaut = dernière page)
$bPrintToFile [optionnel] True pour imprimer dans un fichier. Voir le paramètre $sPrToFileName (par défaut = mot-clé Default = False)
$bCollate [optionnel] True pour combiner des copies multiples (par défaut = mot-clé Default = False)
$sPrToFileName [optionnel] Si $bPrintToFile est définie à True, cet argument spécifie le nom du fichier dans lequel vous souhaitez imprimer.

Valeur de retour

Succès: Retourne l'objet plage imprimée.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - $oExcel n'est pas un objet ou n'est pas un objet application
2 - $vObject n'est pas un objet ou une plage $xlA1 invalide. @error contient le code d'erreur COM
3 - Erreur d'impression de l'objet. @extended contient le code d'erreur COM

En relation

_Excel_Export

Exemples

Exemple 1

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Crée un objet Excel et ouvre un classeur exemple
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Print-Exemple", "Erreur lors de la création de l'objet Excel." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, @ScriptDir & "\Extras\_Excel4.xls", True)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Print-Exemple", "Erreur lors de l'ouverture du classeur '" & @ScriptDir & "\Extras\_Excel4.xls'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; *****************************************************************************
; Imprime la plage A1:B3 de la feuille de calcul active sur l'imprimante par défaut.
; *****************************************************************************
_Excel_Print($oExcel, "A1:B3")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Print-Exemple 1", "Error printing cells." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Print-Exemple 1", "Range successfully printed.")


Exemple 2

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Crée un objet Excel et ouvre un classeur exemple
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Print-Exemple", "Erreur lors de la création de l'objet Excel." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, @ScriptDir & "\Extras\_Excel4.xls", True)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Print-Exemple", "Erreur lors de l'ouverture du classeur '" & @ScriptDir & "\Extras\_Excel4.xls'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; *****************************************************************************
; Imprime la feuille de calcul active sur l'imprimante par défaut.
; *****************************************************************************
_Excel_Print($oExcel, $oExcel.ActiveSheet)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Print-Exemple 2", "Error printing worksheet." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Print-Exemple 2", "Active Worksheet successfully printed.")


Exemple 3

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Crée un objet Excel et ouvre un classeur
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Print-Exemple", "Erreur lors de la création de l'objet Excel." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, @ScriptDir & "\Extras\_Excel4.xls", True)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Print-Exemple", "Erreur lors de l'ouverture du classeur '" & @ScriptDir & "\Extras\_Excel4.xls'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; *****************************************************************************
; Imprime un classeur complet sur l'imprimante par défaut.
; *****************************************************************************
_Excel_Print($oExcel, $oWorkbook)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Print-Exemple 3", "Erreur lors de l'impression du classeur." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "UDF Excel: _Excel_Print-Exemple 3", "Le classeur a été imprimé avec succès.")