UDF > Crypt >


_Crypt_Startup

Initialise la bibliothèque Crypt

#include <Crypt.au3>
_Crypt_Startup ( )

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0.
@error: 1 - Impossible d'ouvrir Advapi32.dll
2 - Impossible d'obtenir le contexte de chiffrement

Remarque

Appeler cette fonction est facultatif.

En relation

_Crypt_Shutdown

Voir aussi

Recherchez CryptAcquireContext dans la bibliothèque MSDN.

Exemple

#include <Crypt.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    _Crypt_Startup() ; Pour optimiser les performances exécuter la bibliothèque crypt, même si ce sont les mêmes résultats affichés dans le cas contraire.

    Local Const $sUserKey = "CryptPassword" ; Déclare un de mot de passe pour déchiffrer/chiffrer les données.
    Local $sData = "... il était une fois un langage sans aucune norme..." ; Données qui seront hachées.

    Local $sOutput = "Les résultats suivants montrent les algorithmes pris en charge pour chiffrer les données." & @CRLF & @CRLF & _
            "Text: " & $sData & @CRLF & @CRLF & _
            "3DES (128bit): " & _Crypt_EncryptData($sData, $sUserKey, $CALG_3DES) & @CRLF & @CRLF & _
            "AES (128bit): " & _Crypt_EncryptData($sData, $sUserKey, $CALG_AES_128) & @CRLF & @CRLF & _
            "AES (192bit): " & _Crypt_EncryptData($sData, $sUserKey, $CALG_AES_192) & @CRLF & @CRLF & _
            "AES (256bit): " & _Crypt_EncryptData($sData, $sUserKey, $CALG_AES_256) & @CRLF & @CRLF & _
            "DES (56bit) : " & _Crypt_EncryptData($sData, $sUserKey, $CALG_DES) & @CRLF & @CRLF & _
            "RC2 (128bit): " & _Crypt_EncryptData($sData, $sUserKey, $CALG_RC2) & @CRLF & @CRLF & _
            "RC4 (128bit): " & _Crypt_EncryptData($sData, $sUserKey, $CALG_RC4)

    MsgBox($MB_SYSTEMMODAL, "Algorithmes pris en charge", $sOutput)

    _Crypt_Shutdown() ; Arrête la bibliothèque crypt.
EndFunc   ;==>Example