Functions > Window >

WinGetClientSize

Obtient la taille de la zone client d'une fenêtre.

WinGetClientSize ( "title" [, "text"] )

Paramètres

title Le titre/hWnd/class de la fenêtre à traiter. Consultez Définition spéciale de titre.
text [optionnel] Le texte de la fenêtre à traiter. La valeur par défaut est une chaîne vide. Consultez Définition spéciale de texte.

Valeur de retour

Succès: Retourne un tableau de 2 éléments contenant les informations suivantes:
    [0] = Largeur de la zone client de la fenêtre
    [1] = Hauteur de la zone client de la fenêtre
Échec: Définit @error <> 0 si la fenêtre n'est pas trouvée.

Remarques

Si la fenêtre est réduite, la largeur et la hauteur retournées sont toutes deux nulles. Toutefois, WinGetClientSize() fonctionne correctement sur les fenêtres cachées (non réduites). Si le titre "Program Manager" est utilisé, la fonction retourne la taille du bureau. Si plusieurs fenêtres correspondent aux critères, la fenêtre activée le plus récemment est utilisée.

En relation

WinGetPos, WinMove

Exemple

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Exécute le Bloc-notes
    Run("notepad.exe")

    ; Attend 10 secondes pour que la fenêtre du bloc-notes apparaisse.
    Local $hWnd = WinWait("[CLASS:Notepad]", "", 10)

    ; Récupére la zone client de la fenêtre du Bloc-notes en utilisant le handle retourné par WinWait.
    Local $aClientSize = WinGetClientSize($hWnd)

    ; Affiche la hauteur et la largeur de la zone client.
    MsgBox($MB_SYSTEMMODAL, "", "Width: " & $aClientSize[0] & @CRLF & "Height: " & $aClientSize[1])

    ; Ferme la fenêtre du Bloc-notes en utilisant le handle retourné par WinWait.
    WinClose($hWnd)
EndFunc   ;==>Example