Functions > Window >

WinActivate

Active (donne le focus) à une fenêtre.

WinActivate ( "title" [, "text"] )

Paramètres

title Le titre/hWnd/class de la fenêtre à activer. Consultez Définition spéciale de titre.
text [optionnel] Le texte de la fenêtre à activer. Par défaut, c'est une chaîne vide. Consultez Définition spéciale de texte.

Valeur de retour

Succès: Retourne le handle de la fenêtre.
Échec: Retourne 0 si la fenêtre n'est pas trouvée ou ne peut pas être activée.

Remarques

Vous pouvez utiliser la fonction WinActive() pour vérifier si WinActivate() a réussi. Si plusieurs fenêtres correspondent aux critères, la fenêtre la plus récente sera activée. WinActivate() fonctionne sur les fenêtres réduites. Toutefois, une fenêtre qui est "Always On Top" peut encore couvrir une fenêtre que vous avez activée.

Après une activation réussie, @extended contient 1 si la fenêtre était déjà active, 2 sinon.

En relation

WinClose, WinKill, WinMove, WinSetState, WinTitleMatchMode (Option)

Exemple

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Exécute le Bloc-notes
    Run("notepad.exe")

    ; Teste si la fenêtre est activée et affiche le résultat.
    If WinActivate("[CLASS:Notepad]", "") Then
        MsgBox($MB_SYSTEMMODAL + $MB_ICONWARNING, "Avertissement", "Fenêtre activée" & @CRLF & @CRLF & "Peut être que votre système est assez rapide.")
    Else
        ; Le bloc-notes s'affichera lorsque MsgBox aura écoulé un délai et l'autorisera.
        MsgBox($MB_SYSTEMMODAL, "", "Fenêtre non activée" & @CRLF & @CRLF & "Mais le bloc-notes est en arrière-plan à cause de MsgBox.", 5)
    EndIf

    ; Teste de nouveau si la fenêtre est maintenant activée et affiche le résultat.
    If WinActivate("[CLASS:Notepad]", "") Then
        MsgBox($MB_SYSTEMMODAL, "", "Fenêtre maintenant activée")
    Else
        MsgBox($MB_SYSTEMMODAL + $MB_ICONERROR, "Erreur", "Fenêtre non activée")
    EndIf

    ; Ferme la fenêtre du Bloc-notes en utilisant le handle retourné par WinWait.
    WinClose("[CLASS:Notepad]", "")
EndFunc   ;==>Example