Functions > Process >

ProcessList

Obtient tous les processus en cours d'exécution (noms et PIDs).

ProcessList ( ["name"] )

Paramètre

name [optionnel] Si un nom est donné, seul les processus de même nom seront retournés.

Valeur de retour

Succès: Retourne le tableau des noms de processus et leur PID (Voir Remarques).
Échec: Définit @error = 1 lorsque la liste ne peut pas être construite.

Remarques

Le tableau retourné est bi-dimensionnel et se compose comme ceci:
    [0][0] = Nombre de processus
    [1][0] = Nom du 1er processus
    [1][1] = ID (PID) du 1er processus
    [2][0] = Nom du 2nd processus
    [2][1] = ID (PID) du 2nd processus
    ...
    [n][0] = Nom du n-ième processus
    [n][1] = ID (PID) du n-ième processus

La liste peut être vide si la position [0][0] contient 0. Dans ce cas aucune @error n'est définie.

En relation

ProcessClose, ProcessExists, ProcessGetStats, ProcessSetPriority, ProcessWait, ProcessWaitClose, WinGetProcess

Exemple

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Exécute le Bloc-notes
    Run("notepad.exe")

    ; Attend 10 secondes pour que la fenêtre du bloc-notes fenêtre apparaisse.
    Local $hWnd = WinWait("[CLASS:Notepad]", "", 10)

    ; Affiche la liste des processus Bloc-notes retournée par PROCESSLIST.
    Local $aProcessList = ProcessList("notepad.exe")
    For $i = 1 To $aProcessList[0][0]
        MsgBox($MB_SYSTEMMODAL, "", $aProcessList[$i][0] & @CRLF & "PID: " & $aProcessList[$i][1])
    Next

    ; Ferme la fenêtre du Bloc-notes en utilisant le handle retourné par WinWait.
    WinClose($hWnd)
EndFunc   ;==>Example