Functions > Network >

InetRead

Télécharge un fichier depuis internet en utilisant le protocole HTTP, HTTPS ou FTP.

InetRead ( "URL" [, options = 0] )

Paramètres

URL URL du fichier à télécharger. Voir les remarques ci-dessous.
options [optionnel]
    $INET_LOCALCACHE (0) = (défaut) Récupère le fichier depuis le cache local si disponible.
    $INET_FORCERELOAD (1) = Force le rechargement depuis le site distant.
    $INET_IGNORESSL (2) = Ignore toutes les erreurs SSL (avec connexions HTTPS).
    $INET_ASCIITRANSFER (4) = Utilise ASCII lors du transfert de fichiers avec le protocole FTP (Ne peut pas être combiné avec le flag $INET_BINARYTRANSFER (8)).
    $INET_BINARYTRANSFER (8) = Utilise BINARY lors du transfert de fichiers avec le protocole FTP (Ne peut pas être combiné avec le flag $INET_ASCIITRANSFER (4)). Ceci est le mode de transfert par défaut si aucun n'est fourni.
    $INET_FORCEBYPASS (16) = Force la connexion en ligne par contournement (Voir Remarques).
Les constantes sont définies dans InetConstants.au3

Valeur de retour

Succès: Retourne une chaîne binaire et assigne à @extended le nombre d'octets téléchargés.
Échec: Retourne "" (chaîne vide) et définit @error <> 0.

Remarques

Internet Explorer 3 ou plus récent doit être installé pour faire fonctionner la fonction.

Le paramètre URL devrait être de la forme "http://www.lesite.com/chemin/fichier.html" - tout comme une adresse que vous tapez dans votre navigateur web.

Pour utiliser un nom d'utilisateur et un mot de passe lors de la connexion, préfixez simplement le nom de serveur avec "nomutilisateur:motdepasse@", par exemple:
"http://nomutilisateur:motdepasse@www.lesite.fr"

Les données retournées sont au format binaire. La fonction BinaryToString() peut-être utilisée pour convertir les données en chaîne.

Par défaut, AutoIt force une connexion avant de démarrer un téléchargement. Les utilisateurs de modem analogique seront invités à passer en ligne ou le numéro sera composé (selon la configuration du système). L'option $INET_FORCEBYPASS (16) désactive ce comportement. Désactiver ce comportement peut-être utile pour les connexions continues (Large bande, LAN). Cependant, il est aussi nécessaire de travailler sur certains problèmes dans Windows Vista et Windows 7.

En relation

FtpSetProxy, HttpSetProxy, HttpSetUserAgent, InetGet, InetGetSize

Exemple

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Lit le fichier sans le télécharger dans un dossier. L'option 'obtenir le fichier à partir du cache local' est choisie.
    Local $dData = InetRead("http://www.autoitscript.com/autoit3/files/beta/update.dat")

    ; Le nombre d'octets lus est retourné en utilisant la macro @extended.
    Local $iBytesRead = @extended

    ; Convertit la chaîne binaire compatible ANSI en une chaîne.
    Local $sData = BinaryToString($dData)

    ; Affiche les résultats.
    MsgBox($MB_SYSTEMMODAL, "", "Nombre d'octets lus: " & $iBytesRead & @CRLF & @CRLF & $sData)
EndFunc   ;==>Example