Functions > GUI > GUISetParameters >


GUISetCursor

Définit l'icône du curseur de la souris pour une GUI.

GUISetCursor ( [cursorID [, override = 0 [, winhandle]]] )

Paramètres

cursorID [optionnel] Id du curseur (Voir Remarques).
override [optionnel] Force le curseur souris requis, même lorsqu'il se trouve sur d'autres contrôles (voir ci-dessous ).
    $GUI_CURSOR_NOOVERRIDE (0) = (par défaut) Ne remplace pas le curseur de la souris par défaut d'un contrôle.
    $GUI_CURSOR_OVERRIDE (1) = Remplace le curseur de la souris par défaut d'un contrôle survolé.

Les constantes sont définies dans GUIConstantsEx.au3.
winhandle [optionnel] Handle Windows retourné par GUICreate() (par défaut, la fenêtre précédemment utilisée).

Valeur de retour

Aucune.

Remarques

Si l'ID du curseur est invalide le curseur standard en forme de flèche sera utilisé.

Habituellement, lorsque vous déplacez le curseur souris sur un contrôle Edit ou un autre contrôle le curseur souris change de forme. L'option "override" vous permet de forcer le curseur souris demandé à être utilisé tout le temps. Remarque: Si vous avez modifié le curseur souris d'un contrôle avec GUICtrlSetCursor(), ce curseur sera toujours affiché.

Pour une liste d'IDs de curseur valides, consultez MouseGetCursor().
CursorID = 16 cachera le curseur souris.

En relation

GUICtrlSetCursor

Exemple

#include <GUIConstantsEx.au3>

Global $g_iIDC = -1, $g_iNewIDC = 0
Global $g_aArray =StringSplit("Hand|AppStarting|Arrow|Cross|Help|IBeam|Icon (obsolete)|No|" & _
"Size (obsolete)|SizeAll|SizeNESW|SizeNS|SizeNWSE|SizeWE|UpArrow|Wait|None", "|", 2)
; Le paramètre flag est défini sur flag = 2 car nous n'avons pas besoin du nombre total d'éléments du tableau

Example()

Func Example()
    HotKeySet("{ESC}", "Increment")

    GUICreate("Press ESC to Increment", 400, 400, 0, 0)

    GUISetState(@SW_SHOW)

    While GUIGetMsg() <> $GUI_EVENT_CLOSE
        If $g_iNewIDC <> $g_iIDC Then
            $g_iIDC = $g_iNewIDC
            GUISetCursor($g_iIDC)
        EndIf
        ToolTip("GUI Cursor #" & $g_iIDC & " (" & $g_aArray[$g_iIDC] & ")")
    WEnd

    GUIDelete()
EndFunc   ;==>Example

Func Increment()
    $g_iNewIDC = $g_iIDC + 1
    If $g_iNewIDC > 16 Then $g_iNewIDC = 0
EndFunc   ;==>Increment