Functions > GUI > GUISetParameters >

GUISetCoord

Définit les coordonnées absolues pour le contrôle suivant.

GUISetCoord ( left, top [, width [, height [, winhandle]]] )

Paramètres

left La coordonnées X du coin supérieur gauche du contrôle.
top La coordonnées Y du coin supérieur gauche du contrôle.
width [optionnel] La largeur du contrôle (par défaut, la largeur utilisée précédemment).
height [optionnel] La hauteur du contrôle (par défaut, la hauteur utilisée précédemment).
winhandle [optionnel] Le handle Windows retourné par GUICreate() (par défaut, la fenêtre précédemment utilisée).

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0.

Remarque

Cette fonction est destinée à être utilisée spécifiquement dans le mode Opt("GUICoordMode", 2). Cette fonction vous permet de définir la position en cours en un point précis et à partir de cette position de créer des contrôles par rangée (x_offset, -1) ou par colonne (-1, y_offset).

En relation

GUICtrlCreate...

Exemple

#include <GUIConstantsEx.au3>

Example()

Func Example()
    Opt("GUICoordMode", 2) ; par rapport au mode cellule

    GUICreate("My GUI Set Coord", 200, 100)
    GUICtrlCreateCheckbox("Check #1", 20, 10, 75)
    GUICtrlCreateCheckbox("Notify #2", 10, -1) ; Prochaine cellule dans la ligne

    GUISetCoord(20, 60)

    GUICtrlCreateButton("OK #3", -1, -1)
    GUICtrlCreateButton("Cancel #4", 10, -1)
    GUICtrlSetState(-1, $GUI_FOCUS)

    GUISetState(@SW_SHOW) ; Affiche la GUI

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example