Functions > GUI > GUICtrlCreate >


GUICtrlCreateDate

Crée un contrôle Date pour une GUI.

GUICtrlCreateDate ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

Paramètres

text Date présélectionnée (toujours au format "aaaa/mm/dd").
left Coordonnée X du coin supérieur gauche du contrôle. Si vous utilisez -1, X sera calculée en fonction de GUICoordMode.
top Coordonnée Y du coin supérieur gauche du contrôle. Si vous utilisez -1, Y sera calculée en fonction de GUICoordMode.
width [optionnel] Largeur du contrôle (par défaut, la largeur utilisée précédemment).
height [optionnel] Hauteur du contrôle (par défaut, la hauteur précédemment utilisé).
style [optionnel] Définit le style du contrôle. Consultez l'Annexe de styles de contrôle GUI.
    Par défaut (-1) : $DTS_LONGDATEFORMAT
    Style forcé : $WS_TABSTOP
exStyle [optionnel] Définit le style étendu du contrôle. Consultez la Table des styles étendus.
    Par défaut (-1) : WS_EX_CLIENTEDGE

Valeur de retour

Succès: Retourne l'ID du nouveau contrôle.
Échec: Retourne 0.

Remarques

Pour obtenir la valeur du contrôle, consultez GUICtrlRead.
Pour définir ou modifier des informations dans le contrôle, Consultez GUICtrlUpdate....

Pour combiner les styles avec le style par défaut, utilisez BitOR($GUI_SS_DEFAULT_DATE, newstyle, ...).
Pour utiliser les valeurs indiquées ci-dessus, vous devez ajouter #include <DateTimeConstants.au3> dans votre script.

Pour formater la date/heure, consultez l'exemple 3 pour comprendre comment utiliser un GUICtrlSendMsg() avec $DTM_SETFORMAT.

Le redimensionnement par défaut est $GUI_DOCKHEIGHT.

En relation

GUICoordMode (Option), GUICtrlRead, GUICtrlSetState, GUIGetMsg

Exemples

Exemple 1

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("My GUI get date", 200, 200, 800, 200)
    Local $idDate = GUICtrlCreateDate("1953/04/25", 10, 10, 185, 20)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    MsgBox($MB_SYSTEMMODAL, "Date", GUICtrlRead($idDate))
    GUIDelete()
EndFunc   ;==>Example


Exemple 2

#include <DateTimeConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("My GUI get date", 200, 200, 800, 200)
    Local $idDate = GUICtrlCreateDate("", 10, 10, 100, 20, $DTS_SHORTDATEFORMAT)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    MsgBox($MB_SYSTEMMODAL, "Date", GUICtrlRead($idDate))
    GUIDelete()
EndFunc   ;==>Example


Exemple 3

#include <DateTimeConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("My GUI get date", 200, 200, 800, 200)
    Local $idDate = GUICtrlCreateDate("1953/04/25", 10, 10, 185, 20)

    ; Sélectionne un format par défaut spécifique
    Local $sStyle = "yyyy/MM/dd HH:mm:ss"
    GUICtrlSendMsg($idDate, $DTM_SETFORMATW, 0, $sStyle)

    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd

    MsgBox($MB_SYSTEMMODAL, "Time", GUICtrlRead($idDate))
EndFunc   ;==>Example


Exemple 4

#include <DateTimeConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("My GUI get time", 200, 200, 800, 200)
    Local $idDate = GUICtrlCreateDate("", 20, 20, 100, 20, $DTS_TIMEFORMAT)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd

    MsgBox($MB_SYSTEMMODAL, "Time", GUICtrlRead($idDate))
    GUIDelete()
EndFunc   ;==>Example