Functions > FileDirDisk >


FileRecycle

Envoie un fichier ou un répertoire dans la corbeille.

FileRecycle ( "source" )

Paramètre

source Le chemin source du/des fichier(s) ou répertoire(s) à recycler. Les caractères génériques sont pris en charge.

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 (signifie généralement que le fichier est utilisé ou n'existe pas).

Remarques

Consultez FileFindFirstFile pour plus de détails sur les caractères génériques.

Pour supprimer un répertoire, il suffit de donner le chemin d'accès sans antislash à la fin.

En relation

DirRemove, FileDelete, FileMove, FileRecycleEmpty

Exemple

#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>

Example()

Func Example()
    ; Crée une constante locale avec le chemin du fichier qui sera lu/écrit.
    Local Const $sFilePath = _WinAPI_GetTempFileName(@TempDir)

    ; Crée un fichier temporaire pour lire les données.
    If Not FileWrite($sFilePath, "Exemple d'utilisation de FileRecycle.") Then
        MsgBox($MB_SYSTEMMODAL, "", "Une erreur est survenue lors de l'écriture dans le fichier temporaire.")
        Return False
    EndIf

    ; Affiche le contenu du fichier en passant le chemin du fichier à FileRead au lieu du handle retournée par FileOpen.
    MsgBox($MB_SYSTEMMODAL, "", "Contenu du fichier the file:" & @CRLF & FileRead($sFilePath))

    ; Supprime le fichier temporaire en l'envoyant à la corbeille.
    Local $iRecycle = FileRecycle($sFilePath)

    ; Affiche un message si le fichier a été supprimé et ouvre la corbeille en cas de succès.
    If $iRecycle Then
        MsgBox($MB_SYSTEMMODAL, "", "Le fichier a été supprimé avec succès.")

        ; Ouvre la corbeille en utilisant le CLSID suivant.
        ShellExecute("::{645FF040-5081-101B-9F08-00AA002F954E}")
    Else
        MsgBox($MB_SYSTEMMODAL, "", "Une erreur est survenue lors de la suppression du fichier.")
    EndIf
EndFunc   ;==>Example