Functions > FileDirDisk >


FileGetSize

Obtient la taille d'un fichier, en octets.

FileGetSize ( "filename" )

Paramètre

filename Nom du fichier à traiter.

Valeur de retour

Succès: Retourne la taille du fichier en octets.
Échec: Retourne 0 et définit @error <> 0.

Remarque

Ne fonctionne pas sur les répertoires.
Divisez le résultat par 1024 pour obtenir l'équivalent en Ko, ou diviser par 1048576 pour obtenir l'équivalent en Mo.

En relation

DriveSpaceTotal, FileGetAttrib, FileGetTime, FileGetVersion

Exemple

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Récupére la taille du fichier (en octets) de l'exécutable AutoIt.
    Local $iFileSize = FileGetSize(@AutoItExe)

    ; Affiche la taille du fichier et la convertit dans une forme lisible.
    MsgBox($MB_SYSTEMMODAL, "", ByteSuffix($iFileSize))
EndFunc   ;==>Example

Func ByteSuffix($iBytes)
    Local $iIndex, $aArray[9] = ['bytes', 'KB', 'MB', 'GB', 'TB', 'PB', 'EB', 'ZB', 'YB']
    While $iBytes > 1023
        $iIndex += 1
        $iBytes /= 1024
    WEnd
    Return Round($iBytes) & $aArray[$iIndex]
EndFunc   ;==>ByteSuffix