Functions > FileDirDisk >

FileGetShortcut

Obtient les propriétés d'un raccourci.

FileGetShortcut ( "lnk" )

Paramètre

lnk Chemin complet et nom du raccourci.

Valeur de retour

Succès: Retourne un tableau qui contient les informations du raccourci. Consultez les remarques.
Échec: Retourne @error = 1 si le raccourci n'est pas accessible.

Remarque

Le tableau retourné par cette fonction est un tableau à une dimension contenant les éléments suivants:
    [0] = Chemin cible de raccourci
    [1] = Répertoire de travail
    [2] = Arguments
    [3] = Description
    [4] = Nom du fichier de l'icône
    [5] = Index de l'icône
    [6] = L'état du raccourcis (@SW_SHOWNORMAL, @SW_SHOWMINNOACTIVE, @SW_SHOWMAXIMIZED)

En relation

FileCreateShortcut

Exemple

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Crée une constante locale avec le chemin du fichier du raccourci.
    Local Const $sFilePath = @DesktopDir & "\FileGetShortcutExample.lnk"

    ; Crée un raccourci sur le bureau pour explorer.exe et définit la combinaison de touches Ctrl+Alt+T, ou en AutoIt ^!t associée au raccourci.
    FileCreateShortcut(@WindowsDir & "\explorer.exe", $sFilePath, @WindowsDir, "/e,c:\", _
            "Tooltip description of the shortcut.", @SystemDir & "\shell32.dll", "^!t", "15", @SW_SHOWMINNOACTIVE)

    ; Consulte les propriétés du raccourci.
    Local $aDetails = FileGetShortcut($sFilePath)
    If Not @error Then
        MsgBox($MB_SYSTEMMODAL, "", "Chemin: " & $aDetails[0] & @CRLF & _
                "Répertoire de travail: " & $aDetails[1] & @CRLF & _
                "Arguments: " & $aDetails[2] & @CRLF & _
                "Description: " & $aDetails[3] & @CRLF & _
                "Nom du fichier icône: " & $aDetails[4] & @CRLF & _
                "Index de l'icône: " & $aDetails[5] & @CRLF & _
                "Etat du raccourci: " & $aDetails[6] & @CRLF)
    EndIf

    ; Supprime le raccourci.
    FileDelete($sFilePath)
EndFunc   ;==>Example