Functions > FileDirDisk >

FileCopy

Copie un ou plusieurs fichiers.

FileCopy ( "source", "dest" [, flag = 0] )

Paramètres

source Chemin du répertoire contenant le(s) fichier(s) à copier. (Les caractères génériques (Wildcards) * et ? sont pris en charge - Voir Remarques)
dest Chemin du répertoire de destination du/des fichier(s) à copier.
flag [optionnel] Ce paramètre détermine s'il faut écraser les fichiers existants.
Est une combinaison des éléments suivants:
    $FC_NOOVERWRITE (0) = (par défaut) n'écrase pas les fichiers existants
    $FC_OVERWRITE (1) = écrase les fichiers existants
    $FC_CREATEPATH (8) = Crée la structure du répertoire de destination, si elle n'existe pas (Voir Remarques).

Les constantes sont définies dans FileConstants.au3

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0.

Remarques

Consultez FileFindFirstFile pour des précisions sur les wildcards.

Le répertoire de destination doit exister, sauf si le paramètre $FC_CREATEPATH(8) est utilisé.
Par exemple le paramètre combiné $FC_OVERWRITE (1) + $FC_CREATEPATH (8), écrase le fichier cible et vérifie la structure du répertoire de destination pour la créer automatiquement si elle n'existe pas.

Certains attributs de fichier peuvent rendre l'écrasement impossible, si c'est le cas consultez FileSetAttrib() pour changer les attributs d'un fichier.

En relation

DirCopy, DirCreate, FileDelete, FileMove

Exemple

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>

Example()

Func Example()
    ; Crée une constante locale avec le chemin du fichier qui sera lu/écrit.
    Local Const $sFilePath = _WinAPI_GetTempFileName(@TempDir)

    ; Crée un fichier temporaire à copier.
    If Not FileWrite($sFilePath, "Exemple d'utilisation de FileCopy.") Then
        MsgBox($MB_SYSTEMMODAL, "", "Une erreur est survenue lors de l'écriture du fichier temporaire.")
        Return False
    EndIf

    ; Copie les fichiers Au3 dans le répertoire temporaire vers un nouveau répertoire appelé Au3Files.
    FileCopy(@TempDir & "\*.au3", @TempDir & "\Au3Files\", $FC_OVERWRITE + $FC_CREATEPATH)

    ; Affiche le répertoire temporaire.
    ShellExecute(@TempDir)
EndFunc   ;==>Example