Functions > FileDirDisk >


FileClose

Ferme un fichier précédemment ouvert.

FileClose ( "filehandle" )

Paramètre

filehandle Le handle du fichier, retourné par un précédent appel à FileOpen().

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 si le handle du fichier n'est pas valide.

Remarques

A la fermeture du script, AutoIt ferme automatiquement tous les fichiers qu'il a ouvert, mais appeler FileClose() est néanmoins une bonne idée.

Cette fonction est aussi utilisée pour fermer un handle de recherche retourné par FileFindFirstFile().

En relation

FileFindFirstFile, FileFindNextFile, FileFlush, FileOpen

Exemple

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>

Example()

Func Example()
    ; Crée une constante locale du chemin du fichier qui sera lu/écrit.
    Local Const $sFilePath = _WinAPI_GetTempFileName(@TempDir)

    ; Crée un fichier temporaire pour lire les données.
    If Not FileCreate($sFilePath, "Exemple d'utilisation de FileClose.") Then
        MsgBox($MB_SYSTEMMODAL, "", "Une erreur est survenue lors de l'écriture dans le fichier temporaire.")
        Return False
    EndIf

    ; Ouvre le fichier pour la lecture et stocke le handle dans une variable.
    Local $hFileOpen = FileOpen($sFilePath, $FO_READ)
    If $hFileOpen = -1 Then
        MsgBox($MB_SYSTEMMODAL, "", "Une erreur est survenue lors de la lecture du fichier.")
        Return False
    EndIf

    ; Lit le contenu du fichier à l'aide du handle retourné par FileOpen.
    Local $sFileRead = FileRead($hFileOpen)

    ; Ferme le handle rtourné par FileOpen.
    FileClose($hFileOpen)

    ; Affiche le contenu du fichier.
    MsgBox($MB_SYSTEMMODAL, "", "Contenu du fichier:" & @CRLF & $sFileRead)

    ; Supprime le fichier temporaire.
    FileDelete($sFilePath)
EndFunc   ;==>Example